本篇收录 3 节6,053 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 核对本服-l短途传送和回复；私讯111恢复约克只匹配原作者写死的qxlg角色。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
2020年9月7日稿，以短途recall和容错走位串联东角、月神六任务，自动打开比恩的小盒子。
- 准备物品格与购买、交通钱，10秒后从recall 7、recall -l 13买焦油和稻草人开始。
- 依次艾温、约克，再recall 2及-l 12入月神，做苏西、比恩和吉伯特；比恩问gift后双击小盒子。
- 吉伯特牛只提交选项1至5，然后继续达武与克利的戒指任务，最后stop。
- 每个NPC附近设置目标o、p，模糊走最多500次后restart；物品过多提示清包、20秒后重试。
02这份代码的适用限制
03完整代码
311 行原文
#新手東角月神教區25萬經驗任務
#本代碼適用於ikok2.x，最後更新於2020-09-07
#任務包含：1.約克破水槽；2.艾溫與稻草人；3.憂傷的蘇西；4.比恩的困擾；5.吉伯特的牛；
#艾溫(even) 座標：141,177 地址碼：9240753 ，look碼：look 2@9240753
#約克(york) 座標：175,614 地址碼：11469414 look碼：look 2@11469414
#蘇西(suzie) 座標：71,214 地址碼：6453270
#拉尼爾(lanier) 座標：65,224 地址碼：4260064 look碼：look 2@4260064
#比恩(bean) 座標：69,162 地址碼：4522146
#迪倫馬特(durrenmatt) 座標：178,238 地址碼：11665646
#吉伯特(gilbert) 座標：24,234 地址碼：1573098 look碼：look 2@1573098
#乳牛(cow) 座標：22,228 地址碼：1442020 look碼：look 2@1442020
%public_bc
jump:約克:新手冒險者(qxlg)告訴你 : 111
%scene begin
do (true)
2:follow_bc:follow %n
enddo
5:wait_bc:wait
10:wait_bc:tell %n 等待指令，10秒後自動開始！
jump 任務物品
%scene 任務物品
do (true)
5:recall_bc:recall 7
enddo
wait15
do (true)
5:recall_bc:recall -l 13
enddo
run 157,301 10
run 163,288 10
2:look_bc:look 2@10944809
1:buy_bc:buy 1 tar
1:buy_bc:buy 1 scarecrow
run 157,301 10
run 156,303
jump 艾溫
%bc buy_bc
call:no-load:你帶的東西太多了。
next::你買下一灌焦油(tar)。
next::你買下一個稻草人(scarecrow)。
next:60:對不起, 這樣東西已經賣完了, 請待會兒再來。
call:no-load:你的負重不夠了!
%scene no-load
2::tell %n 你帶的東西太多了，請清理揹包
20::tell %n 等待20秒重試
return retry
#-----------------------------------------艾溫與稻草人-----------------------------------------#
#艾溫(even) 座標：141,177 地址碼：9240753 ，look碼：look 2@9240753
%scene 艾溫
run 152,305
run 149,295
run 138,246
run 128,215
run 141,182
(o=140)
(p=180)
call 模糊走
3:look_bc:look 2@9240753
2::clear_action
5:give_bc:give scarecrow to ewen
log 001-艾溫與稻草人已完成
jump 約克
#-----------------------------------------約克破水槽-----------------------------------------#
#約克(york) 座標：175,614 地址碼：11469414 look碼：look 2@11469414
%scene 約克
do (true)
5:recall_bc:recall -l 12
enddo
run 153,490 10
run 148,503
run 175,576
run 178,584
run 177,612
#防止有人站位，再走幾步
(o=176)
(p=612)
call 模糊走
3:look_bc:look 2@11469414
2::clear_action
5:give_bc:give tar to york
log 002-約克破水槽已完成
jump 月神教區
%scene 月神教區
do (true)
5:recall_bc:recall 2
enddo
wait15
do (true)
5:recall_bc:recall -l 12
enddo
run 198,280
(o=199)
(p=278)
call 模糊走
#往月神教區的路標
do (true)
3:recall_bc:look 1@12976404
2:recall_bc:enter entrance
enddo
jump 蘇西
#-----------------------------------------憂傷的蘇西-----------------------------------------#
#蘇西(suzie) 座標：71,214 地址碼：6453270
#拉尼爾(lanier) 座標：65,224 地址碼：4260064 look碼：look 2@4260064
%scene 蘇西
run 65,130
run 50,157
run 45,229
run 59,260
run 66,246
run 58,230
run 66,214
(o=66)
(p=215)
call 模糊走
2:ask_bc:ask suzie about trouble
2:ask_bc:ask suzie about sorrow
2:ask_bc:ask suzie about someone
2:ask_bc:ask lanier about suzie
2:ask_bc:ask lanier about event
2:ask_bc:ask suzie about event
2:ask_bc:ask suzie about rose
2::helpsuzie dohelp
3:look_bc:look 2@4260064
2::telllanier dotell
log 003-憂傷的蘇西已完成
jump 比恩
#-----------------------------------------比恩的困擾-----------------------------------------#
#比恩(bean) 座標：69,162 地址碼：4522146
#迪倫馬特(durrenmatt) 座標：178,238 地址碼：11665646
%scene 比恩
run 78,188
run 73,181
run 66,166
(o=65)
(p=165)
call 模糊走
2:ask_bc:ask bean about knee
2:ask_bc:ask bean about business
2::helpbean dohelp
#----------去找迪倫馬特----------#
run 73,181
run 107,217
run 119,240
run 125,252
run 175,234
(o=176)
(p=235)
call 模糊走
3:look_bc:look 2@11665646
2::givebox dogive
#----------返回比恩處----------#
run 125,252
run 119,240
run 107,217
run 73,181
run 66,166
(o=65)
(p=165)
call 模糊走
2:ask_bc:ask bean about gift
15::@&dclick 小盒子
do (true)
2:follow_bc:follow %n
enddo
log 004-比恩的困擾已完成
jump 吉伯特
#-----------------------------------------吉伯特的牛-----------------------------------------#
#吉伯特(gilbert) 座標：24,234 地址碼：1573098 look碼：look 2@1573098
#乳牛(cow) 座標：22,228 地址碼：1442020 look碼：look 2@1442020
%scene 吉伯特
run 73,181
run 86,207
run 65,247
run 59,260
run 33,227
run 25,242
run 23,234
#防止有人站位，再走幾步，並限定時間
(o=23)
(p=230)
call 模糊走
1:ask_bc:ask gilbert about cow
1:ask_bc:ask gilbert about coprosterol
1:look_bc:look 2@1442020
2::dochoice 1
2:look_bc:look 2@1442020
2::dochoice 2
2:look_bc:look 2@1442020
2::dochoice 3
2:look_bc:look 2@1442020
2::dochoice 4
2:look_bc:look 2@1442020
2::dochoice 5
2:look_bc:look 2@1573098
log 005-吉伯特的牛已完成
10::time
jump 達武
%scene 達武
run 25,242
run 18,260
run 19,306 50
5:ask_bc:ask davout about trouble
5:ask_bc:ask davout about ring
5:look_bc:buyring dobuy
5:ask_bc:ask 7864482 klee about ring
5:ask_bc:ask 7864482 klee about price
5:look_bc:buyring dobuy
5:look_bc:look 2@1245492
5:look_bc:givering dogive
jump 完成
%scene 完成
2::sing 全部完成！
stop
%scene open_e
1::open e
return retry
%scene open_n
1::open n
return retry
%bc recall_bc
break:3:你進入區域%*
%bc run_bc
next::@position
retry:0.34:你正忙著呢 !
%bc go_e_bc
call:open_e:你過不去。
%bc go_n_bc
call:open_n:你過不去。
%bc give_bc
next:1:你給艾溫一個稻草人(scarecrow)。
next:1:你給約克一灌焦油(tar)。
%bc click_bc
next:1:%*你確定要離開這個地區嗎？
next:1:這是一個訓練用的假人，破破爛爛的身上%*
break::%+你要祈求時空魔法陣送你到哪個地區 ??
%bc look_bc
next:1:你看到一個溫吞的老好人坐在櫃檯前發呆，他就是本店的店長霍克。
next:1:%*有人可以到霍克的雜貨店中幫我買一個稻草人就好了....咳... 咳%*
next:1:%*需要一些焦油來補，不知道你是否願意幫我去東城門的鐵匠買嗎？%*
#---------蘇西和拉尼爾------------------
next:1:%*你要不要告訴拉尼爾，蘇西的真正想%*
next:1:恭喜你完成幫助蘇西的任務，你得到五萬經驗值。
#---------比恩的困擾--------
next:1:%*你要不要把箱子交給迪倫馬特呢？%*
#---------吉伯特的牛--------
next:1:%*請選擇治療乳牛的方法：%*
next:1:%*一聽到自己心愛的乳牛終於便便了，吉伯特非常地%*
#---------達武任務----------
next:1:達武露出高興的神情：「非常感謝你的幫忙，那我就靜待你的好訊息了。」
next:1:克利給你一枚結婚戒指(beautiful ring)。
next:1:%*你要不要把戒指交給達武？
next:1:恭喜你完成了幫助達武的心願，得到五萬點經驗值。
%bc ask_bc
#---------蘇西和拉尼爾------------------
next:1:%*蘇西憂傷地望了你一眼，緩緩地搖搖頭%*
next:1:%*蘇西緩緩地抬起頭，眼光漠然地望著前方%*
next:1:%*蘇西避開你的眼光：「何必問我他是誰呢%*
next:1:%*拉尼爾突然臉一紅，有點結巴地問你%*
next:1:%*拉尼爾歪著頭，似乎在回想事情的發生經過%*
next:1:%*你把拉尼爾剛剛對你說的事情，向蘇西重複一次%*
next:1:%*蘇西有點不好意思地說：「難道你不%*
#---------比恩的困擾--------
next:1:%*唉…老毛病了，天氣一變化，膝蓋%*
next:1:%*牧場主人定了樣東西，本來是早就該送去給他了，誰知道%*
next:1:%*你要不要幫助比恩呢？%*
next:1:%*比恩看到你來後，急忙問你%*
#---------吉伯特的牛--------
next:1:%*吉伯特看起來頗為煩惱的樣子：「我養的乳牛中%*
next:1:%*吉伯特有點煩躁地說：「我也只是猜測啦，月神教%*
#--------達武任務---------
next:1:達武看看身旁的坎達絲，把你拉到一旁，小聲地%*
next:1:%*達武歪著頭想了一會後，在你耳邊小%*
next:1:你跟克利說了前因後果後，克利略想了一會%*
next:1:%*克利思考了一會後說：「既然是達武%*
%bc follow_bc
break:0.5:你並沒有跟著誰。
%scene 模糊走
(t=0)
do (%sx >= o+2 || %sx <= o-2 || %sy >= p+4 || %sy <= p-4)
0.5::@&run [%vo,%vp]
::%it
#show %vt
if (t>500)
restart
(t=0)
endif
enddo
if (%sx!=o)||(%sy!=p)
1::@&run [%vo,%vp]
1:run_bc:
endif
return next
%scene 地址碼模糊走
(calit = q)
(o = calit / 65536)
(p = calit % 65536)
(t=0)
do (%sx >= o+2 || %sx <= o-2 || %sy >= p+4 || %sy <= p-4)
0.5::@&run [%vo,%vp]
::%it
#show %vt
if (t>500)
restart
(t=0)
endif
enddo
if (%sx!=o)||(%sy!=p)
1::@&run [%vo,%vp]
1:run_bc:
endif
return next↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。