本篇收录 3 节5,882 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 先完成神迹法帽，留物品格；虹戒虽负重0仍占背包格。台服S3的recall 15与三楼路线须对应本服。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
完成神迹法帽后调查三名嫌疑人，脚本处理问话与交任务，虹戒NPC和凯必须由玩家完成击杀。
- tell自己1从recall 15开始，2在摩亚达三楼寇拉兹接任务；3进入三人初问，4／5／6分别续谢拉、库鲁、查尔斯org问话，7续交任务。
- 逐个问rainbow dragon、sunbow，再根据回复问org并交虹戒；脚本等待，玩家手动杀对应NPC取回虹戒。
- 取得虹戒触发回寇拉兹交戒，问tracer的master，然后去凯附近等待手动战斗。
- 原心得建议第一形态拉到11,108，第二形态让帮手打至奄奄一息后离开，由任务号拿最后击杀；原推荐妖祭或技能练满的狂系帮手。
- 凯死亡提示触发回三楼问master；六类非衣奖励提示可重做，三类锁ID衣服结束。若喝药回调与死亡提示冲突，可tell自己7恢复交任务。
02这份代码的适用限制
03完整代码
233 行原文
#大地國服【火★紅-red】組織出品
#前置需已解完神蹟法帽任務
#需手動打虹戒的NPC（根據代碼提示直接殺取即可）
#殺死“凱”得到提示後，代碼將自動啟動前往交任務
#心得：將第一形態的凱（只會普攻）拉至座標11,108處，殺至第二形態（會魔法）就可以用打手號打至“奄奄一息”後下線，由任務號擊殺。
#打手號推薦：妖祭師，滿cast狂系
%public_bc
next:3:你祈求神把你帶回烏魯 ...
retry:3:這裡沒有這個人。
retry:1:你正忙%*
jump:begin:傳送師說道：你的錢不夠。
jump:kolaz:你從%*的屍體裡搜出了你拿給他的虹戒。
jump:kolaz:你從%*的屍體裡搜出了另一個虹戒。
jump:reward:你殺死了彩虹龍組織的主使者 ...
jump:start:%+(%*)告訴你 : 1
jump:jierenwu:%+(%*)告訴你 : 2
jump:第一段:%+(%*)告訴你 : 3
jump:cela:%+(%*)告訴你 : 4
jump:kurus:%+(%*)告訴你 : 5
jump:charles:%+(%*)告訴你 : 6
jump:reward:%+(%*)告訴你 : 7
break::%+(%*)告訴你 : 繼續
#自動喝藥水段（如需請刪掉前面“#”自行開啟，需要在低於多少血之後喝水也自行修改。會影響凱死亡後面的代碼）：
#call:drink:%h < 400
%scene begin
5::tell %n 【1】tell 自己 1 開始任務。預留負重拿“戒指”。如已經在摩亞達3樓，可直接tell 2開始任務。2-7為中途任務掉線而設立的；
5::tell %n 【2】3樓kolaz開始；如已經在摩亞達3樓，可直接tell 自己 2開始任務；
20::tell %n 【3】謝拉庫魯查爾斯問話；【4】謝拉問org段；【5】庫魯問org段；【6】查爾斯問org段；【7】擊殺“凱”交任務
#開始任務
%scene start
call rtm
call rtm3
run 50,33 25
jump jierenwu
%scene jierenwu
loop2
2:look_bc:ask 3276828 franto kolaz about help
endloop
2:look_bc:ask 3276828 franto kolaz about list
jump 第一段
%scene 第一段
call rtm
run 6,171 15
loop2
2:look_bc:ask cela about rainbow dragon
endloop
2:look_bc:ask cela about sunbow
run 92,198
2:look_bc:ask kurus about rainbow dragon
2:look_bc:ask kurus about rainbow dragon
2:look_bc:ask kurus about sunbow
run 98,154 30
run 98,132 10
run 98,88 25
run 92,18 35
2:look_bc:ask charles about rainbow dragon
2:look_bc:ask charles about rainbow dragon
2:look_bc:ask charles about sunbow
jump charles
#######謝拉org段#####
%scene cela
call rtm
run 6,171
2:cela_bc:ask cela about org
2:cela_bc:ask cela about org
jump kurus
%scene gcela
2::@&look 謝拉
1:celajz_bc:give_sunbow sunbow
loop500000
30::tell %n 已經給了“戒指”，現在直接擊殺“謝拉”獲得“虹戒”，“虹戒”負重0，注意揹包物品數量。
endloop
%bc celajz_bc
next::謝拉把弄著戒指，看看你，又看看戒指，過了好長的一段時間才露出了釋懷的笑容說：這麼多年了！這麼多年了！終於又有了新的夥伴加入我們日漸消弱的組織，看樣子摩亞達終將再歸於我們了。
謝拉咦的一聲，他用不讓第三者聽到的聲音問道：難不成你也是夥伴之一？不可能，不可能，這麼機密的事不是隨隨便便就可以讓外面的人知道的。謝拉狐疑看看了四周，吞了吞口水，遲疑地問：你….你…難不成有什麼信物可以證明你的身分嗎？
######庫魯org段#######
%scene kurus
run 1,185
run 94,185
2:kurus_bc:ask kurus about org
2:kurus_bc:ask kurus about org
jump charles
%scene gkurus
2::@&look 庫魯
1:kurujz_bc:give_sunbow sunbow
loop500000
30::tell %n 已經給了“戒指”，現在直接擊殺“庫魯”重新獲得“虹戒”，“虹戒”負重0，注意揹包物品數量。
endloop
%bc kurujz_bc
next::庫魯把弄著戒指，看看你，又看看戒指，過了好長的一段時間才露出了釋懷的笑容說：這麼多年了！這麼多年了！終於又有了新的夥伴加入我們日漸消弱的組織，看樣子摩亞達終將再歸於我們了。
#臺服S3-R15直接到達摩亞達“庫魯”處
%scene kulu
10:recall_bc:recall 15
jump kurus
#####查爾斯org段#####
%scene charles
#call rtm
#run 1,185 30
#run 94,185
#run 97,90
run 92,18
2:charles_bc:ask charles about org
5:charles_bc:ask charles about org
jump cela
%scene gcharles
2::@&look 查爾斯
1:chajz_bc:give_sunbow sunbow
loop500000
30::tell %n 已經給了“戒指”，現在直接擊殺“查爾斯”獲得“虹戒”，“虹戒”負重0，注意揹包物品數量。
endloop
%bc chajz_bc
next::查爾斯把弄著戒指，看看你，又看看戒指，過了好長的一段時間才露出了釋懷的笑容說：這麼多年了！這麼多年了！終於又有了新的夥伴加入我們日漸消弱的組織，看樣子摩亞達終將再歸於我們了。
####-給“寇拉茲”戒指準備打“凱”-#####
%scene kolaz
call rtm
call rtk
2::look 2@3276828
1::give_sunbow sunbow
1::give_sunbow sunbow
run 48,62
run 36,105
run 31,119
run 34,127
1::ask tracer about master
1::ask tracer about master
call rtm
run 11,127 120
run 4,100 120
run 12,26 120
loop1000
60::tell %n 成功擊殺凱後，指令碼自動進行下一步，未成功擊殺凱，指令碼不會繼續下一步。如擊殺“凱”出現指令碼不會繼續，說明%public_bc的喝藥水和交任務剛好重複代碼不執行，請自行tell自己7。
endloop
#####--交任務---#####
#最後交任務，領取任務獎勵！
%scene reward
call rtm
call rtm3
2:rwwc_bc:ask 3276828 franto kolaz about master
stop
%bc rwwc_bc
jump:wwc:佛蘭託．寇拉茲給你一頂時光之帽(juncture of hat)。
jump:wwc:佛蘭託．寇拉茲給你一隻虹光古戒(carbuncle ring)。
jump:wwc:佛蘭託．寇拉茲給你一條閃耀之煉(aglare necklace)。
jump:wwc:佛蘭託．寇拉茲給你一件疾風之麾(moderate gale of wind)。
jump:wwc:佛蘭託．寇拉茲給你一雙化龍戰靴(fossil of boots)。
jump:wwc:佛蘭託．寇拉茲給你一雙靈幻之手(ghostly gloves)。
jump:wancheng:佛蘭託．寇拉茲給你一件幻化錦袍(brocaded robe)。
jump:wancheng:佛蘭託．寇拉茲給你一件流光之服(robe of streamer)。
jump:wancheng:佛蘭託．寇拉茲給你一件虹龍鎧甲(acton of dragons)。
#########
%scene wwc
2::sing 任務完成，但是很可惜並未得到鎖ID的衣服。現在前往“寇拉茲”處，如需重複任務請tell自己2，或者在代碼%scene wwc處自行修改自動啟動代碼。
run 50,33 25
jump begin
%scene wancheng
50::sing 任務完成！恭喜你獲得了鎖ID衣服，凱的任務也告一段落。【火★紅(red)】製作
#########################################
#烏魯去莫亞達
%scene rtm
10:recall_bc:recall 15
return
%scene rtk
run 20,157 10
run 37,104
run 67,36
do(true)
2:look_bc:look 1@4390947
enddo
2::enter enterance
run 46,32 5
run 57,54
run 27,111
run 21,100
do(true)
5:look_bc:look 1@1179747
enddo
2::enter enterance
run 50,33 30
return
%scene rtm3
run 20,157 10
run 37,104
run 67,36
do(true)
2:look_bc:look 1@4390947
enddo
2::enter enterance
run 46,32 5
run 57,54
run 27,111
run 21,100
do(true)
5:look_bc:look 1@1179747
enddo
2::enter enterance
return
%scene drink
0.34::drink potion
return retry
%bc sing_bc
jump:reward:你殺死了彩虹龍組織的主使者 ...
%bc look_bc
next:0.5:%*彩虹龍(rainbow dragon)夥伴之間的認證信物--虹戒(sunbow)。
next:0.5:佛蘭託．寇拉茲給你一張破舊的羊毛皮(auld woolskin)。
next:0.5:謝拉側著頭想了一下。
next:0.5:謝拉用力地搜尋腦中的印象，豆大的汗滴沿著他的臉龐流下。%*你可以問問他有關虹戒的事，測試他會不會有什麼奇怪的反應。
next:0.5:你特意把戒指在謝拉麵前晃啊晃，不過謝拉仍是一副很疑惑的模樣，甚至還露出覺得你這個人真是奇怪的眼神，看來謝拉應該是跟這個組織沒有關係。
next:0.5:庫魯慎重地看著你，似乎正在思考著下一步的對策。
next:0.5:突然之間他厲聲的問道：你怎麼知道這件事的，這個派系早就已經消失了，這麼多%*測試他會不會有什麼奇怪的反應。
next:0.5:你特意把戒指在庫魯面前晃啊晃，不過庫魯仍是一副很疑惑的模樣，甚至還露出覺得你這個人真是奇怪的眼神，看來庫魯應該是跟這個組織沒有關係。
next:0.5:查爾斯搔搔頭想了一下，露出疑惑的表情。
next:0.5:查爾斯狐疑回答你說：這是什麼東西？新的牛種嗎？還是別的物品，我不懂你問的是什麼，看樣子我真的該補充我的知識了%*查爾斯似乎是很困惑的模樣，同時卻又露出奇怪的眼神，不過你想好像一時之間也問不出所以來，看來還是先去查察別的嫌疑者吧。
jump:charles:綜合3個嫌疑犯的反應，你可以感覺到查爾斯所知的似乎比其餘人知道的更多，於是你想再一次詢問他有關(org)的事。
jump:cela:綜合3個嫌疑犯的反應，你可以感覺到謝拉所知的似乎比其餘人知道的更多，於是你想再一次詢問他有關(org)的事。
jump:kulu:綜合3個嫌疑犯的反應，你可以感覺到庫魯所知的似乎比其餘人知道的更多，於是你想再一次詢問他有關(org)的事。
break::樓梯
%bc cela_bc
next::謝拉睜大眼睛望著你，顯然不知道你在說什麼。
next::謝拉搖搖頭，說道 : 沒聽說過。
jump:gcela:謝拉咦的一聲，他用不讓第三者聽到的聲音問道：難不成你也是夥伴之一？不可能，不可能，這麼機密的事不是隨隨便便就可以讓外面的人知道的。謝拉狐疑看看了四周，吞了吞口水，遲疑地問：你….你…難不成有什麼信物可以證明你的身分嗎？
%bc kurus_bc
next::庫魯說道 : 嗯....這我可不清楚，你最好問問別人吧。
next::庫魯搖搖頭，說道 : 沒聽說過。
jump:gkurus:%*看看了四周，吞了吞口水，遲疑地問：你….你…難不成有什麼信物可以證明你的身分嗎？
%bc charles_bc
jump:gcharles:查爾斯咦的一聲，他用不讓第三者聽到的聲音問道：難不成你也是夥伴之一？不可能，不可能，這麼機密的事不是隨隨便便就可以讓外面的人知道的。查爾斯狐疑看看了四周，吞了吞口水，遲疑地問：你….你…難不成有什麼信物可以證明你的身分嗎？
%bc recall_bc
next:0.34:你祈求神把你帶回%*
retry:2:你剛剛才轉換過區域%*
retry:2:你正忙著%*
retry:1:你現在正在戰鬥中 ...
retry:1:你上一個動作還沒有完成 !
retry:0.34:你正忙著呢 !↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。
对照原资料
查看 1 份来源与保存记录
台湾渔夫资料站
【台服S3 】ikok潜伏的威胁“凯”(摩亚达)-【手动打NPC，注意负重】
查看保存记录
- 来源编号
k2-8- 资料集
- ikok代码2
- 保存时间
- 2026-09-07
- 原始位置
- 【台服S3 】ikok潜伏的威胁“凯”(摩亚达)-【手动打NPC，注意负重】.txt