本篇收录 3 节5,019 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 大法具回时、时跳、吸魂术、冰刃、风暴、电击、恶魔击与冥思；设置六坑、locate1、大臣和假人。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
六坑轮转、吸魂开战与冰刃配时空风暴，空闲时接受组织成员操作口令。
- 六站6/26/46,145与185；开打前四轮回时、时跳、冥思，首站locate1，再切下一站。
- MP<2000继续恢复；遍历24格cast soul_steal和回时，之后stun、自动time_storm与手动ice_lance，时跳循环至脱战。
- 空闲可help、run、组队、收我、开我、抓我；战斗回调另保留组队和抓人。死亡回国训练cast、dart、dodge、meditate、wizard_magic。
02这份代码的适用限制
03完整代码
253 行原文
%name 古惑仔女大臣協會專用大法帶人機
%variable e
(0,2)
(0,3)
(1,2)
(1,3)
(2,2)
(2,3)
(7,3)
(8,2)
(8,3)
(9,2)
(9,3)
(10,2)
(0,20)
(0,19)
(1,20)
(1,19)
(2,20)
(2,19)
(7,19)
(8,20)
(8,19)
(9,20)
(9,19)
(10,20)
%variable f
[6,145] 6,145
[26,145] 26,145
[46,145] 46,145
[46,185] 46,185
[26,185] 26,185
[6,185] 6,185
%public_bc
goto:death:慢慢地你終於又有了知覺....
%scene begin
50:wait_bc:sing ^[36m古惑★暗龍☆帶人機器人等待你的指示。◎要想知道機器人的使用方法請：^[33mtell chenxingp help，^[36m機器人會給您詳細說明，或者點選帶人區門口的留言板檢視詳細說明。◎^[36m請被帶的玩家站在沒坑中間下面的骷髏上，地面資訊為：被帶。^[30m◎一次學滿技能和魔法的快捷設定：alias train train 100 $* 技能 alias study study 101 $* 魔法
::set two_magic 0
::@&run %vf
( h = 0 )
do ( h <= 3 )
5:retime_bc:cast retime on
3:blink_bc:time_blink
50:meditate_bc:meditate
::@&run %vf
( h = h + 1 )
loop
if ( %of == 0 )
50:locate_bc:locate 1
endif
::%if
goto fight
#這一段有些重複，是因為用KOK和zkok顯示的不一樣
%bc wait_bc
goto:help:%+告訴你：help
goto:run:%b%+告訴你：run(%*)
goto:party:%b%+(%$)告訴你：組隊
#goto:fight:%b%+(%$)告訴你：開打
goto:accept:%b%+(%$)告訴你：收我
goto:banish:%b%+(%$)告訴你：開我
goto:summon:%b%+(%$)告訴你：抓我
goto:city:%b%+(%$)告訴你：city(%*)
goto:train:%b%+(%$)告訴你：回家學技能
goto:wield:%b%+(%$)告訴你：wield(%*)
goto:wear:%b%+(%$)告訴你：wear(%*)
goto:recall:%b%+告訴你 : recall %*
goto:help:%+告訴你 : help
goto:run:%b%+告訴你 : run(%*)
goto:party:%b%+(%$)告訴你 : 組隊
#goto:fight:%b%+(%$)告訴你 : 開打
goto:accept:%b%+(%$)告訴你 : 收我
goto:banish:%b%+(%$)告訴你 : 開我
goto:summon:%b%+(%$)告訴你 : 抓我
goto:city:%b%+(%$)告訴你 : city(%*)
goto:train:%b%+(%$)告訴你 : 回家學技能
goto:wield:%b%+(%$)告訴你 : wield(%*)
goto:wear:%b%+(%$)告訴你 : wear(%*)
goto:recall:%b%+告訴你：recall %*
#提示機器人如何使用
%scene help
2::sing “tell %n 組隊”能邀請你加入隊伍。
#2::sing “tell %n 開打”開始打。
2::sing “tell %n recall X”能回到出發點。
2::sing “tell %n city(zhouyu)”能自動移動到城市zhouyu或其他的城市。
#(zhouyu是一個城市的ID，也可以是別的任何一個可以進入的城市)
2::sing 首先“join %n”申請，然後“tell %n 收我” 能加入城邦。
2::sing “tell %n 開我”開除戶籍。
2::sing “tell %n 抓我”召喚本城人民。
2::sing 如果我死了，“tell %n 回家學技能”，我就能回去自己學技能。
2::sing 如果我死了，給我+5智力的裝備，然後“tell %n wear(裝備的ID)”，我就能穿上這件衣服，謝謝了。
2::sing ^[31m注意：以上所有這些功能除了組隊、抓人命令外，只在我空閒的時候才會有效。如果在戰鬥或做其他動作時，機器人對tell的指令不作反映。
goto begin
#跑位程式碼
%scene run
5::@&run [%1]
::sing 跑到(%1)了，請繼續下一個操作。
goto begin
#組隊程式碼
%scene party
::party form
::party invite %1
::sing ^[30m組隊邀請完畢，如果你在其他隊伍裡，請先^[33mparty disband^[30m脫離原來的隊伍，然後再重新組隊。加入隊伍後請輸入^[33mparty follow^[30m取消隊伍跟隨，否則會影響您帶打經驗。
goto begin
#收人程式碼
%scene accept
::accept %1
goto begin
#開人程式碼
%scene banish
::banish %1
goto begin
#抓人程式碼
%scene summon
::summon %1
goto begin
%bc run_bc
next::到了
#打NPC程式碼
%scene fight
::set two_magic 1
::set spell ice_lance
5:retime_bc:cast retime on %va
3:blink_bc:time_blink
5:float_bc:cast float on
3:blink_bc:time_blink
# do ( %M != %m )
do ( %m < 2000 )
5:retime_bc:cast retime on
3:blink_bc:time_blink
50:meditate_bc:meditate
loop
::set spell stun
foreach e
5:steal_bc:cast soul_steal on %pe
3:blink_bc:time_blink
5:retime_bc:cast retime on
3:blink_bc:time_blink
loop
goto goon
%bc fight_bc
call:fightparty:%b%+(%$)告訴你：組隊
call:fightparty:%b%+(%$)告訴你：組隊
call:fightsummon:%b%+(%$)告訴你：抓我
call:fightsummon:%b%+(%$)告訴你：抓我
%scene fightparty
::party form
::party invite %1
::order %1 to party join %n
::order %1 to party follow
::sing ^[30m組隊邀請完畢，如果你在其他隊伍裡，請先^[33mparty disband^[30m脫離原來的隊伍，然後再重新組隊。加入隊伍後請輸入^[33mparty follow^[30m取消隊伍跟隨，否則會影響您帶打經驗。
return next
%scene fightsummon
::summon %1
return next
%scene goon fight_bc
::set two_magic 1
::set spell ice_lance
5:stun_bc:cast stun on
3:blink_bc:time_blink
::set spell time_storm
do
5:ice_bc:cast ice_lance on
3:blink_bc:time_blink
loop
::sing ^[32m搞定，繼續下一個操作。
goto begin
%scene danger
::set two_magic 1
::set spell stun
do
5:demon_bc:cast demon_strike on
3:blink_bc:time_blink
5:retime_bc:cast retime on
3:blink_bc:time_blink
loop
jump begin
%bc retime_bc
next::難以言喻的力量自四處向%*集中, %*的身體似乎有些不尋常的變化 ...
next::回時術的力量依然在%*的身上作用著。
next::你附近沒有這個人。
retry::你上一個動作沒有完成, 不能施法!
retry::你現在不能對他施法。
retry::但是什麼事也沒發生。
retry::你正忙著呢 !
next::你的法力不夠 !!
%bc blink_bc
retry::你試圖擾動時空能流，但是失敗了。
retry::你才剛擾動過時空能流，時空能流還不穩定。
retry::你的身體突然由內向外放出光芒，以極快的速度閃了幾閃。
next::你現在並不忙碌。
%bc float_bc
next::%*緩緩從地面升起 ...
next::%*已經飄浮著了。
retry::你上一個動作沒有完成, 不能施法!
next::你的法力不夠 !!
%bc meditate_bc
retry:1:你正忙著呢 !
jump:danger:戰鬥中無法冥思 !
next::你現在精神正好，不需要冥思。
retry:2:你的精神還沒有恢復平靜，不能冥思。
next:2:你現在身體狀況太差了，無法集中精神 !
next::你深深地吸了一口氣，從深沈的冥思中醒來 !
%bc steal_bc
next::%*臉上露出如在夢魘般的驚慌的神色, 努力地掙扎著醒來 ...
next::你面前的符咒突然爆炸, 在你身上爆發出強烈的黑暗力量。
# next::你在你和%*之間劃出一道符咒 ...你唸道 : 黑闇之蠱啊 ～～盡情的吸取%*的力量吧 ...
next::%*鎮定地與你的法力抗衡，一點都不受影響。
retry::你上一個動作沒有完成, 不能施法!
next::但是什麼事也沒發生。
next::你還沒決定要加入 pk，不能殺人 !
continue::那裡沒有任何人。
next::你的法力不夠 !!
%bc stun_bc
retry::你上一個動作沒有完成, 不能施法!
retry::但是什麼事也沒發生。
next::你造出一個電場，電擊所有在場的敵人。
next::你現在不在戰鬥中。
retry::你的法力不夠 !!
%bc ice_bc
retry::你上一個動作沒有完成, 不能施法!
retry::但是什麼事也沒發生。
next::你喃喃念道 : 梅依雷依 ～～ 雷依波特 ～ 雷依凱特 ...
break::你現在不在戰鬥中。
retry::你的法力不夠 !!
%bc demon_bc
next::一隻帶著長翼的巨大惡魔從六芒星中掙扎地冒出來 ...
retry::你上一個動作沒有完成, 不能施法!
next::但是什麼事也沒發生。
break::你現在不在戰鬥中。
next::你的法力不夠 !!
%bc recall_bc
next::你祈求神把你帶回%* ...
retry:2:你剛剛才轉換過區域，請稍待一會兒再試 !
retry::你正忙著呢 !
%scene death
10::recall 1
5::home me
::sing 回家了
10:click_bc:@&click 假人
::train cast
::train dart
::train dodge
::train meditate
::train wizard_magic
::home me
goto begin
%bc click_bc
next::這是一個訓練用的假人，破破爛爛的身上佈滿了刀劍的刺砍痕跡。
%bc locate_bc
next::到了
retry:2:你才使用傳送不久，沒辦法這麼快再用。
retry:2:你剛剛才轉換過區域，請稍待一會兒再試 !
retry::你正忙著呢 !↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。