本篇收录 3 节16,731 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 需完整阅读开头别名配置：升级位置、技能与魔法序列、穿1～6、身上留金500、银行留10万、各钱坑路线及收益地点。
- 原作者限定人形快攻MOB布局；牛头人等须另外适配。准备回时、时空风暴、冰矛、时跳、冥思及银行补给条件。
- 远程口令laowangzx会执行捕获文本，其他口令可转款、训练或退出；原朋友名单只用于10亿通知，没有限制这些公共口令的发送者。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
王谐生2018年11月27日的IKOK 3.0五坑程序，以两次时空风暴和冰矛清怪，并串起拾卖、存取款、训练、死亡恢复与远程指令。
- 按原作者示意配置五个28人快攻坑及地点别名：第一、四、五坑在上，第二、三坑在下，横差20、纵差40。
- 启动统计身上与银行金币，检查保护令；手持超过1000万尝试存款，累计超过10亿通知朋友。
- MP低于800先回时、冥思，等MOB后用两次时空风暴配时跳，再用ice_lance收尾；反复失败达到计数后重启本轮。
- 拾地面金币及尸体物品，按柜台距离移动，出售到预先记录的负重。该负重是在穿装后卖掉其余物品建立。
- 按配置循环五坑；需要时回城存取钱、买保护令、训练属性技能，死亡后回原点拾尸、穿装并续跑。
- 按原口令处理送款、钱坑统计、训练、存款、重启、穿装和下线；显示按当前时段线性推算的日收益。
02这份代码的适用限制
03完整代码
1347 行原文
#王諧生編寫
#奉獻日期2018-11-27 9:01:36
#使用版本ikok3.0
#只能用於人形npc跑得快的,牛頭人請自行更改時風段
#預設放2個時風+冰刃結束戰鬥,特殊請自己更改
#此代碼中不包含自動購買月卡等功能,請自行手動購買vip
#其他變數自己察看
#需要設定的快捷方式如下
#升級位置 tell 你的id 30,30
#按序號設定你要學習的技能
#技能1 train 100 meditate
#技能2 train 100 cast
#技能3 train 100 magic
#技能4 train 100 wizard_magic
#按序號設定你需要學習的魔法
#魔法1 study retime
#改成你要穿的裝備id
#穿1 wear renlian
#穿2 wear renguan
#穿3 wear renpao
#穿4 wear renpi
#穿5 wear renjiezhi
#穿6 wield rbang
#顧名思義,用於練功,送錢,跑車伕等其他情況
#身上留金幣 tell 你的id 500
#每坑的定位方式,坑方向為
#145
#23
#location可以不用管.預設第一坑位置是30,30
#這是設定的第一坑也是home me的座標
#錢坑位置 tell 你的id 30,30
#錢坑1 home me
#預設為y+40
#錢坑2 locate 2
#預設為x再+20,可以不用管,死了之後自動定位
#錢坑3 cast location on me
#預設為y再-40
#錢坑4 locate 1
#預設為x再+20
#錢坑5 run 70,30
#作為買魂魄保護令等等突發情況的銀行應急留底
#銀行留金幣 tell 你的id 100000
#穿衣服出現沒有快捷方式,就不再往下穿
#繞坑方式可在坑位計算段落自行更改,預設為
#145
#23
#具體見快捷方式以配合,施法的定位術如果是空自動記憶
#每次死亡會打下一坑
#代碼會自動撿取坑內暴屍金幣
#櫃檯超出視野會自動跑到櫃檯視野邊緣賣
#代碼無需設定負重,上線即賣光,自動記憶淨負重
#代碼無需設定櫃檯座標,在坑內即可
#務必留夠銀行保底金幣,預設10萬,用以意外死亡可以買保護令,以免點技能遭受損失
#身上留金幣是用以增加坐車使用等其他功能,在scene跑到目標段自行編寫其他
#變數map和變數mudi,都是一樣的,用以比對位置
#變數mode是每一個地方去的方式,功能可在scene跑到目標段自行編寫
#變數friend是自己的白名單,銀行超過10億白名單輪發一次訊息,提醒收錢.
#tell 你的id 密碼sq 會在打完撿完之後到r2車伕送金幣,具體在使用時體會
#tell 你的id 密碼sj 會在打完撿完之後自動升級
#tell 你的id 密碼qk 會告訴打錢的情況
#tell 你的id 密碼cq 會在打完之後存錢
#tell 你的id 密碼fw 會重新復位
#tell 你的id 密碼cyf 會讓他立即穿上衣服
#laowang視為預設密碼,可替換成你自己的密碼
#其他功能見公共bc段
#送錢在log資料夾會產生日誌記錄,具體請使用中體會
#可以使用非大臣號,非城主,在傳送方式需改動,具體使用中體會
#產生卡位等情況在1分鐘之後會自動重置
#代碼會自動記憶所打的每一坑的座標
#死亡之後會暫時跳過被打死的那坑
#代碼會在重啟時候穿上所有裝備之後賣光一次裝備
#所以無需設定負重,無需設定武器id等等其他本代碼中沒有提到的任何設定
%public_bc
jump:死了:%b死亡地點%*座標 %#,%#
call:執行命令:%b%*(%$)%*laowangzx%*
call:送錢人:%b%*(%$)%*laowangsq
call:彙報情況:%b%*(%$)%*laowangqk
call:升級並復位:%b%*(%$)%*laowangsj
call:存錢並復位:%*laowangcq
restart::%*laowangfw
call:穿衣服:%*laowangcyf
shutdown:600:帳號從別處登入!
shutdown::%*laowang永久下線
shutdown::%*laowang下線
(hbf=0)::你的生理時鐘慢慢恢復到原來的狀態。
(hbf=1)::難以言喻的力量自四處向你集中, 你的身體似乎有些不尋常的變化 ...
(hbf=1)::回時術的力量依然在你的身上作%*
(scms=scms+1)::你盤膝坐了下來, 開始冥思。
%var map
烏魯
史坎佈雷
打錢
練功
%var mudi
烏魯
史坎佈雷
打錢
練功
%var mode
傳送
傳送
傳送
傳送
%var way
recall 1
recall 2
錢坑1
練功定位
%var friend
weixiaoc
weixiaob
%var hbname
%var sqname
%var mingling
%scene 跑到目的
if ($vmap=="初始值")
call 使用位置
endif
if ($vmap==$vmudi)
show 區域一致
return next
endif
(mode=$omudi)
(way=$omudi)
if ($vmode=="傳送")
do(true)
3:傳送:%vway
enddo
endif
(map=$vmudi)
call 記錄位置
return next
%scene 執行命令
(mingling=%3)
::%vmingling
return
%scene 看收益
(l=0)
return next
do(true)
5:收益:sc
enddo
(l=%1*3600+%2*60+%3)
if (%vl==0)
jump 我是要打錢
else
show 有收益
endif
return next
%bc 收益
break:0.34:%b%*收益時間仍有%#小時%#分%#秒%*
%bc consi
break:0.34:你用挑釁的眼光%*
%scene begin
(ctpsx=0)
(ctpsy=0)
(ctposn=0)
(ysq=0)
(scms=0)
(map="初始值")
jump 看時間
%scene 進入正軌
call 總數錢
(stgld=ttgld)
if (ttgld<10000)
log 打錢,共有%vttgld金幣.
endif
if (ttgld>=10000)&&(ttgld<100000000)
(rtgld=ttgld/10000)
log 打錢,共有%vrtgld萬(%vttgld)金幣.
endif
if (ttgld>=100000000)
(rtgld=ttgld/100000000)
log 打錢,共有%vrtgld億(%vttgld)金幣.
endif
(stattm=%now)
call 身上留金幣
call 銀行留金幣
call 獲取升級位置
if (ttgld>=1000000000)
foreach friend
do(true)
3:告訴人:tell %vfriend 我總共超過10億了,儘快收
enddo
loop
endif
if (%g>10000000)
(mudi=2)
call 跑到目的
call 升級位置
call 存錢
endif
jump 我是要打錢
%scene 我是要打錢
call 看保護令
call 自動冰刃
(mudi=2)
call 跑到目的
call 穿衣服
(e=0)
(hbf=0)
jump 打錢
%scene 打錢
if (ysq==1)
(ysq=0)
call 總數錢
if (ttgld>5000000)
jump 送錢
else
do(true)
2:告訴人:tell %vsqname 我還沒有5千萬,這次不值得送給你
enddo
endif
endif
if (e==0)
call 上次坑位
else
call 記錄坑位
endif
(zuo=c*65536+d)
(mu=%sx*65536+%sy)
if (zuo != mu)
loop8
0.5:錢坑跑:錢坑%ve
endloop
endif
(o=c)
(p=d)
call 準確走
if (e==1)
(hbf=0)
call 存錢
call 統計效益
do(true)
5:記錄:alias 金幣情況 tell %n 歷時%vdhh時%vdmm分%vdss秒,收穫%vntgld金幣,預%vegld金幣每天
enddo
if (ttgld>=1000000000)
foreach friend
do(true)
3:告訴人:tell %vfriend 我總共超過10億了,儘快收
enddo
loop
endif
endif
call 關雙施
(mingsi=0)
do (%m<800)
do(mingsi==0)
if (hbf==0)
loop8
1:hs:cast retime on
if (hbf==1)
break
endif
endloop
endif
1:冥思:meditate
enddo
1:冥思:
enddo
jump 確定數量
%scene 確定數量
(jishu=0)
do(true)
loadmapvar a nnpc
::%znnpc
::%dnnpc
if ($onnpc==27)
jump 開始打
endif
(u=27-$onnpc)
1::sing 少%vu個
if ($onnpc >10)
(jishu=jishu+1)
if (jishu >15)
0.4::sing 還是沒有28個,但是超過10個,我等不及了
jump 開始打
endif
endif
if (hbf==0 && %m<%M )
loop20
0.5:cshs:cast retime on
endloop
endif
enddo
jump 開始打
%bc cshs
break::難以言喻的力量自四處向你%*
break:0.34:回時術的力量依然在你的身上作%*
%scene 開始打
(shife=0)
(ts=0)
do(shife<2)
0.4:shifeng:cast time_storm
0.4:shifeng:time_blink
enddo
(brfb=0)
(jishu=0)
do(true)
1:ice_bc:cast ice_lance on a
if (brfb == 0)
0.4:ice_bc:time_blink
endif
(jishu=jishu+1)
if (jishu>50)
restart
endif
enddo
loadmapvar gold fdgld
foreach fdgld
(q= fdgld )
call 轉換座標
call 模糊走
loop3
0.4:get_bc:get %vfdgld
endloop
loop
if (hbf==0)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop10
0.4:hstb:time_blink
endloop
endif
(seq=0)
if(%heft>heavy)
(fqc=0)
else
(seq=1)
endif
(o=c)
(p=d)
call 模糊走
loadmapvar counter ctposn
(q=ctposn)
(nea=q)
call 轉換座標
(ctpsx=o)
(ctpsy=p)
loadmapvar corpse f
::%df
show %of
(last=0)
(lstcps = $of - 3)
(nowcps =0)
::%zf
greedy f t %vnea
foreach t
if (seq != fqc)
(q=t)
call 轉換座標
call 模糊走
call 點櫃檯
else
(q=t)
call 轉換座標
call 起步走
call 點櫃檯
(jishu=0)
do(%heft>heavy)
0.21:sell_bc:sell 1
(jishu=jishu+1)
if (jishu>20)
show 網路卡,等5秒
5::
(jishu=0)
endif
enddo
loop35
(npos=%sx*65536+%sy)
if (npos == t)
break
endif
0.2::
endloop
endif
loadround f s
(fqc=0)
foreach s
(fqc=fqc+1)
loop
(seq=0)
foreach s
(nowcps = nowcps + 1)
remove f %vs
(jishu=0)
do(%heft==heavy)
0.4:get_bc:get ALL_ITEM_IN %vs
(jishu=jishu+1)
if (jishu>20)
show 網路卡,等5秒
5::
(jishu=0)
endif
enddo
(seq=seq+1)
if (hbf == 0 && %m< %M && nowcps < lstcps)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop5
0.4:hstb:time_blink
endloop
endif
if (seq != fqc)
(jishu=0)
do(%heft>heavy)
0.21:sell_bc:sell 1
(jishu=jishu+1)
if (jishu>20)
show 網路卡,等5秒
5::
(jishu=0)
endif
enddo
endif
if (hbqk==1)
call 總數錢
do(true)
if (ttgld<10000)
3:告訴人:tell %vhbname 飄%vsiwang,冥%vscms,現有%vttgld,歷時%vdhh時%vdmm分%vdss秒,收穫%vntgld金幣,預%vegld金幣每天
endif
if (ttgld>=10000)&&(ttgld<100000000)
(rtgld=ttgld/10000)
3:告訴人:tell %vhbname 飄%vsiwang,冥%vscms,現有%vrtgld萬(%vttgld)金,歷%vdhh時%vdmm分%vdss秒,獲%vntgld金,預%vegld金每天
endif
if (ttgld>=100000000)
(rtgld=ttgld/100000000)
3:告訴人:tell %vhbname 飄%vsiwang,冥%vscms,現有%vrtgld億(%vttgld)金,歷%vdhh時%vdmm分%vdss秒,獲%vntgld金,預%vegld金每天
endif
enddo
(hbqk=0)
endif
loop
loop
if (ysq==1)
(ysq=0)
call 總數錢
if (ttgld>5000000)
jump 送錢
else
do(true)
2:告訴人:tell %vsqname 我還沒有5千萬,這次不值得送給你
enddo
endif
endif
if (ysj==1)
(ysj=0)
do(true)
2:告訴人:tell %vhbname 我去升級技能了
enddo
jump 升級復位
endif
if (ycq==1)
(ycq=0)
if (%g>1000000)
do(true)
2:告訴人:tell %vhbname 我去存錢了,我身上有%g金幣
enddo
jump 存錢復位
else
do(true)
2:告訴人:tell %vhbname 我身上金幣不足百萬,所以我不去存錢
enddo
endif
endif
jump 打錢
%bc 冥思
(mingsi=1)::你深深地吸了一口氣，從深沈的冥思中醒來 !
(mingsi=1)::你現在精神正好，不需要冥思。
(mingsi=1)::你的精神還沒有恢復平靜，不能冥思。
(mingsi=0)::你的精神恢復平靜，又可以冥思了。
%bc 關雙施
break:0.34:關閉環境變數%*
%bc 自動惡魔
break:0.34:你把環境變數自動法術設定%*
%bc 開雙施
break:0.34:你把環境變數雙重法術設定成 開啟。
%bc shifeng
(shife=shife+1)::你緊握著雙手喃喃念著不知%*
%bc 戰鬥關係
break:0.34:你祈求神把你帶回第一新手教學區 ...
%bc 自動冰刃
break:0.34:你把環境變數自動法術設定成 ice_lance。
%bc 自動回時
break:0.34:你把環境變數自動法術設定成 retime。
%bc 錢坑跑
break:0.34:你才使用傳送不久，沒辦法這麼快再用。
break:0.34:你進入區域%*
break:0.34:你在原地跳了跳。
call:定位點跑:你並未記憶定位點。
wait:4:你剛剛才轉換過區域，請稍待一會兒再試 !
%bc 點櫃檯
break::這是一張生意場所經常使用來記帳的櫃檯。
%bc ice_bc
break:0.34:你現在不在戰鬥中。
(brfb=1)::你喃喃念道 : 梅依雷依 ～～ 雷依波特 ～ 雷依凱特 ...
next:0.34:你上一個動作沒有%*
%bc hs
(hbf=1)::你低頭凝神念著某個時空禁咒%*
%bc hstb
break:0.34:你的身體突然由內向外放出光芒%*
break:0.34:你現在並不忙%*
%bc get_bc
break:0.34:%*沒有任何東西。
break:0.34:這裡沒有任何容器。
break:0.34:你的附近沒有這種東西。
break:0.34:這裡沒有任何東%*
break::你撿起%*
break:0.34:你現在不能拿這具屍體的東西。
%bc sell_bc
call:點櫃檯:what ?
call:點櫃檯:你無法與你視線範圍外的商店進行交易 ...
jump:存錢復位:你身上的金幣超%*法獲得超出的部分。
%bc recall_bc
retry:0.34:你上一個動作沒有%*
retry:3:你剛剛才轉換過區域%*
break:5:你祈求神把你帶回%*
%bc 記錄
break:0.34:設定完成 !
%scene 記錄位置
do(true)
5:記錄位置:alias 我的位置 tell %n 我在%vmap
enddo
return next
%bc 記錄位置
break:0.34:設定完成 !
%bc 我的位置
break:0.34:%b%*)告訴你 : 我在%*
call:位置空:what ?
%scene 使用位置
(jishu=0)
do(true)
3:我的位置:我的位置
(jishu=jishu+1)
if (jishu>20)
goto 位置空
endif
enddo
(map=%1)
return next
%scene 位置空
(way=1)
do(true)
3:傳送:%vway
enddo
(map=$oway)
call 記錄位置
restart
%bc 傳送
break:0.34:你進入區域%*
break:0.34:你在原地跳了跳。
%bc 保護
break:0.34:烏魯市政廳釋出的保護令%*
goto:買保護令:你要看什麼 ?
%scene 看保護令
do(true)
3:保護:look protection order
enddo
return next
%scene 買保護令
(mudi=0)
call 跑到目的
if (%m>50 && hbf==0)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop10
0.4:hstb:time_blink
endloop
endif
(o=343)
(p=649)
call 模糊走
(o=364)
(p=699)
call 模糊走
if (%m>50 && hbf==0)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop10
0.4:hstb:time_blink
endloop
endif
if (%g<15000)
show 身上沒錢買保護令取錢
(l=0)
do(true)
5:看錢:sc
::%il
if (l>5)
::%iu
goto 大記錄
endif
enddo
if (%1>15000)
do(true)
(o=364)
(p=699)
call 模糊走
5:銀行:@&click 銀行
enddo
do(true)
15:卡技:withdraw 15000
enddo
else
log 沒錢購保護令
return next
endif
endif
do(true)
5:點市長:look 2@24117945
enddo
do(true)
5:點市長:buy_protect
enddo
do(true)
5:記錄:alias 小記錄 tell %n %vyea年%vmth月%vdat日,%hh點%mm分%ss秒,購保護令
enddo
if (%m>50 && hbf==0)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop10
0.4:hstb:time_blink
endloop
endif
return next
%bc 看錢
next:0.5:%iu%*身上帶著 %* 枚金%*體恢復損壞度%*
break:0.34:%b%*銀行裡還有 %# 枚金%*
%bc 銀行
break:0.34:%b%*行裡還有 %# 枚金幣。
%bc 點市長
break:0.4:烏魯市政廳秘書，是市長的雙生弟弟，喜歡和哥哥穿一樣的服裝。
break:0.4:隆秘書給你一份魂魄保護令(protection order)。
break:0.4:%*隆秘書%*已經有神的護佑了，請努力對抗邪惡的敵%*
%scene 總數錢
do(true)
1:看銀行錢:sc
enddo
(ttgld=%2+%g)
return next
%scene 看銀行錢
do(true)
1:看銀行錢:sc
enddo
(l=%2)
return next
%bc 看銀行錢
break:0.34:%b%*上帶著%*枚金幣, 銀行裡還有 %* 枚金%*
break:0.34:%*上帶著%*枚金%*
%scene 關雙施
do(true)
0.5:關雙施:set two_magic 0
enddo
return next
%scene 開雙施
loop2
0.34:開雙施:set two_magic 1
endloop
return next
%scene 自動回時
do(true)
0.5:自動回時:set spell retime
enddo
return next
%scene 自動冰刃
do(true)
0.5:自動冰刃:set spell ice_lance
enddo
return next
%bc 賣光
next:0.7:%iu這個東西你正裝備著 !
next:0.7:%iu%*能把這個東西賣掉 !
break:0.34:%*沒有這種東西。
call:點櫃檯:what ?
call:點櫃檯:你無法與你視線範圍外的商店進行交易 ...
jump:存錢復位:你身上的金幣超過了%*超出的部分。
%bc gss
break:0.34:關閉環境變數﹕雙重法術。
%scene 穿衣服
(u=0)
do(true)
::%iu
3:撿屍體:穿%vu
enddo
return next
%bc 撿屍體
next:1:你撿起%*
call:加力量:你拿不動了 !
break:0.34:%*沒有任何東西。
break:0.34:這裡沒有任何容器。
break:0.34:你的附近沒有這種東西。
next:0.34:你上一個動作還沒有完成 !
next:1:你裝備%*。
next:1:你穿上%*。
next:1:你戴上%*。
next:1:你拿起%*。
next:0.4:你已經裝備著了。
next:0.34:你身上沒有這樣東西。
break:0.34:what ?
%bc 錢坑位置
break:0.34:%b%*)告訴你 : %#,%#
call:沒位置:what ?
%scene 沒位置
4::tell %n 沒有設定好位置,或者格式錯誤.例如座標10,10格式如下
show alias (命令的名稱) tell 你的id 10,10
return next
%scene 點櫃檯
(o=%sx)
(p=%sy)
(memx=o)
(memy=p)
if (%sx>ctpsx+5)
(o=5+ctpsx)
endif
if (%sx<ctpsx-5)
(o=ctpsx-5)
endif
if (%sy>ctpsy+10)
(p=10+ctpsy)
endif
if (%sy<ctpsy-10)
(p=ctpsy-10)
endif
if (o!=memx || p!=memy)
call 模糊走
endif
loop7
0.4:點櫃檯:@&click 櫃檯
endloop
if (o!=memx || p!=memy)
show 點櫃檯的賣
do(%heft > heavy)
0.21:sell:sell 1
(jishu=jishu+1)
if (jishu>20)
show 網路卡,等5秒
5::
(jishu=0)
endif
enddo
(o=memx)
(p=memy)
call 準確走
endif
return next
%bc sell
break:0.34:你不能把這個東西賣%*
goto:點櫃檯:what ?
goto:點櫃檯:你無法與你視線範圍外的商店進行交易 ...
%scene 定位點跑
(o=c)
(p=d)
call 準確走
6:記憶術:cast location on here
return next
%bc 記憶術
next:3:你把你的「念」留在這裡了。
%scene 轉換座標
(calit=q)
(o= calit / 65536)
(p= calit % 65536)
return next
%scene 模糊走
(endpst=o*65536+p)
(nowpst=%sx*65536+%sy)
if (nowpst != endpst)
call 起步走
do (%sx >= o+2 || %sx <= o-2 || %sy >= p+4 || %sy <= p-4)
0.5:run_bc:
enddo
loop50
(nowpst=%sx*65536+%sy)
if (nowpst == endpst)
return next
endif
0.1::
endloop
endif
return next
%scene 準確走
(nowpst=%sx*65536+%sy)
(endpst=o*65536+p)
if (npos != endpst)
call 起步走
do(true)
(nowpst=%sx*65536+%sy)
if (nowpst == endpst)
return next
endif
0.1::
enddo
endif
return next
%scene 起步走
(endpst=o*65536+p)
(zqpst=%sx*65536+%sy)
(jishu=0)
do(true)
(nowpst=%sx*65536+%sy)
if(nowpst == endpst || nowpst != zqpst)
return next
endif
0.1::@&run %vendpst
(nowpst=%sx*65536+%sy)
(jishu=jishu+1)
if (jishu > 100)
restart
endif
if(nowpst == endpst || nowpst != zqpst)
return next
endif
0.1::
(nowpst=%sx*65536+%sy)
if(nowpst == endpst || nowpst != zqpst)
return next
endif
0.1::
(nowpst=%sx*65536+%sy)
if(nowpst == endpst || nowpst != zqpst)
return next
endif
enddo
return next
%bc 金幣
break:0.34:%b%*)告訴你 : %#
%bc 卡技
break:0.34:這是一張銀行使用來記帳的櫃檯。
break:0.34:你在你帳戶存入%*金幣。
break:0.34:你身上沒有那麼多金幣。
break:0.34:你從你的帳戶提出 %* 枚金幣。
break:0.34:你要提領多少錢呢?
break:0.34:指令格式: deposit <數量>
break:0.34:你的帳戶裡沒有這麼多錢。
goto:銀行滿:銀行最多隻能%*個金額。
goto:身上滿:你最多能擁帶%*請換個金額。
%scene 身上滿
do(true)
5:銀行:@&click 銀行櫃檯
enddo
(u=1000000000-%g)
do(true)
15:卡技:withdraw %vu
enddo
return next
%scene 銀行滿
do(true)
5:銀行:@&click 銀行櫃檯
enddo
(u=1000000000-%1)
if (u!=0)
do(true)
15:卡技:deposit %vu
enddo
endif
do(%g==1000000000)
20::tell %vfriend 我在%sx,%sy.銀行,身上錢都滿了,一直等待送錢,請及時處理
::%ifriend
if (ysq==1)
jump 送錢
endif
enddo
return next
%scene 身上留金幣
do(true)
3:金幣:身上留金幣
enddo
(ssljb=%1)
return next
%scene 銀行留金幣
do (true)
3:金幣:銀行留金幣
enddo
(yhljb=%1)
return next
%scene 彙報情況
(hbname=%1)
(hbqk=1)
return
%scene 送錢人
(sqname=%1)
(ysq=1)
return
%scene 升級並復位
(hbname=%1)
(ysj=1)
return
%scene 存錢並復位
(hbname=%1)
(ycq=1)
return
%scene 存錢復位
(mudi=2)
call 跑到目的
call 升級位置
call 存錢
restart
%scene 存錢
if (%g > ssljb)
do(true)
5:卡技:@&click 銀行櫃檯
enddo
(u=%g-ssljb)
loop2
3:卡技:deposit %vu
endloop
endif
return next
%scene 統計效益
(ntime=%now)
(dtime=ntime-stattm)
(dhh=0)
(dmm=0)
(dss=0)
(dtime=ntime-stattm)
if (dtime>=3600)
(dhh=dtime/3600)
endif
if (dtime - dhh*3600 >= 60)
(dmm=(dtime-dhh*3600)/60)
endif
(dss=dtime-dhh*3600-dmm*60)
call 總數錢
(ntgld=ttgld-stgld)
(dtime=ntime-stattm)
(momoda= ntgld*10 / dtime)
(egld=momoda*8640)
return next
%bc 告訴人
break:0.34:你告訴%*
break:0.34:沒有這個人....。
%scene 送錢
(ysq=0)
if (%g<1000000000)
do(true)
2:告訴人:tell %vsqname 我剛剛忙完,我先去取錢,請您在recall 2的41,168,等待我給你錢
enddo
call 取錢
(u=%g-ssljb)
do(true)
2:告訴人:tell %vsqname 我已經取了錢,最好先準備好%vu金幣的空位
enddo
else
do(true)
2:告訴人:tell %vsqname 我剛剛忙完,請您在recall 2的41,168,等待我給你錢
enddo
endif
(mudi=1)
call 跑到目的
(o=41)
(p=169)
call 模糊走
(sonqan=%g)
if (%g>ssljb)
(u=%g-ssljb)
do (true)
3:給錢:give %vu to %vsqname
enddo
endif
(jishu=5)
do(true)
if (%g<=ssljb)||(jishu<=1)
break
endif
(u=%g-ssljb)
8:還給錢:tell %vsqname 我一直給你%vu金幣,說不要我就回去,我還給%vjishu次就回去,也可以告訴我密碼+數目
2:還給錢:give %vu to %vsqname
(jishu=jishu-1)
enddo
if (%g<=ssljb)
if (sonqan>%g)
(u=sonqan-%g)
endif
log 帶%vsonqan,給%vsqname了%vu,身上還有%g金幣
restart
endif
if (%g>ssljb)
goto 存錢復位
restart
endif
restart
%scene 給數目
(jishu=5)
(sqname=%1)
do(%g>ssljb)
(u=%g-ssljb)
if (u>%2)
2:再給錢:give %2 to %vsqname
8:再給錢:
else
8:再給錢:tell %vsqname 對不起了啊,我最多隻能給你%vu金幣,重新告訴我密碼+數目,說不要我就回去
endif
2:再給錢:tell %vsqname 我還給%vjishu次就回去
(jishu=jishu-1)
if (%g<=ssljb)||(jishu<=1)
break
endif
enddo
if (sonqan>%g)
(u=sonqan-%g)
endif
log 帶%vsonqan,用給數目方式總共給%vsqname了%vu,身上還有%g金幣
if (%g>ssljb)
goto 存錢復位
restart
endif
restart
%scene 還是超
::tell %vsqname 你要%2金幣,你還是無法拿,重新告訴我密碼+數目
return
%scene 超上限
(u=%g-ssljb)
do(true)
2:告訴人:tell %vsqname 我給你%vu金幣,你金幣上限了,拿不了
enddo
return
%bc 再給錢
break:0.34:你至少要給一枚金幣吧。
break:0.34:你沒有這麼多錢。
break:0.34:%*(%$)%*不要
next:1:%b%*(%$)告訴你 : laowang%#
call:還是超:對方金額將會超過上限，無法給予!
%bc 還給錢
break:0.34:你至少要給一枚金幣吧。
break:0.34:你沒有這麼多錢。
break:0.34:%*(%$)%*不要
goto:給數目:%b%*(%$)告訴你 : laowang%#
call:超上限:對方金額將會超過上限，無法給予!
%bc 給錢
break:0.34:你給%*枚金幣。
break:0.34:你的周圍沒有這個人。
break:0.34:你至少要給一枚金幣吧。
break:0.34:你沒有這麼多錢。
break:0.34:對方金額將會超過上限，無法給予!
%scene 升級復位
(sqname=%1)
do(true)
0.4:告訴人:tell %vsqname 我去升級了
enddo
call 取錢升技能
restart
%scene 取錢升技能
call 取錢
show 升技能
do(true)
4:點草人:@&click 假人
enddo
(u=1)
do(true)
3:學技能:技能%vu
enddo
(u=1)
do(true)
5:點草人:@&click 魔法石碑
enddo
do(true)
3:學技能:魔法%vu
enddo
call 存錢
do(true)
0.4:告訴人:tell %vsqname 我升級完畢了
enddo
return next
%bc 點草人
break:0.4:這是一個訓練用的假人，破破爛爛%*
break:0.4:這是一個佈滿魔法銘文的石碑，散發出%*
%bc 學技能
next:0.4:%iu你%*的熟練度%*
break:0.4:%iu這裡不提供這種訓練 !
next:0.4:%iu你需要%*枚金幣來提升%*!
next:1:你的%*提升%*提升而消耗了!
next:0.4:%iu你的%*這裡所能訓練的最大值了。
next:0.4:%iu你的相關魔法知識不足以理解更高深的法術了。
break:0.34:what ?
%scene 取錢復位
call 取錢
restart
%scene 取錢
(mudi=2)
call 跑到目的
call 升級位置
do(true)
5:銀行:@&click 銀行櫃檯
enddo
if (%1>yhljb || %1!=0)
(u=%1-yhljb)
if (u!=0)
loop2
3:卡技:withdraw %vu
endloop
endif
endif
return next
%scene 升級位置
(o=sjwzx)
(p=sjwzy)
if (%sx > (o+2) || %sx < (o-2 )|| %sy > (p+4) || %sy < (p-4))
loop3
3:錢坑跑:錢坑1
endloop
endif
call 模糊走
return next
%scene 獲取升級位置
do(true)
2:錢坑位置:升級位置
enddo
(sjwzx=%1)
(sjwzy=%2)
return next
%scene 坑初始
do(true)
1:記錄:alias 打錢跳坑 tell %n 現在第1坑
enddo
(u=0)
return next
%bc 跳坑
break:0.34:%b%*)告訴你 : 現在第%#坑
call:坑初始:what ?
break:0.34:刪除 alias :%*
break:0.34:你並沒有設%*
%scene 上次坑位
do(true)
2:錢坑位置:錢坑位置
enddo
(c=%1)
(d=%2)
do(true)
1:跳坑:打錢跳坑
enddo
(e=%1)
::%ie
if (e==2)
(d=d+40)
endif
if (e==3)
(c=c+20)
(d=d+40)
endif
if (e==4)
(c=c+20)
endif
if (e==5)
(c=c+40)
endif
if (e>5)
(e=1)
endif
do(true)
1:記錄:alias 打錢跳坑 tell %n 現在第%ve坑
enddo
(zuo=c*65536+d)
(mu=%sx*65536+%sy)
if (zuo != mu)
loop8
0.5:錢坑跑:錢坑%ve
endloop
endif
(o=c)
(p=d)
call 準確走
(heavy=0)
do(true)
0.4:點櫃檯:@&click 櫃檯
enddo
(u=1)
do (true)
1:賣光:sell %vu
enddo
(heavy=%heft)
return next
%scene 坑位計算
::%ie
if (e==2)
(d=d+40)
endif
if (e==3)
(c=c+20)
endif
if (e==4)
(d=d-40)
endif
if (e==5)
(c=c+20)
endif
if (e>5)
(c=c-40)
(e=1)
endif
return next
%scene 記錄坑位
call 坑位計算
do(true)
1:記錄:alias 打錢跳坑 tell %n 現在第%ve坑
enddo
return next
%scene 看時間
(jishu=0)
do(true)
5:時間:time
(jishu=jishu+1)
if (jishu>12)
(map=0)
(way=$omap)
(mode=$omap)
do(true)
3:傳送:%vway
enddo
call 記錄位置
restart
endif
enddo
if (%2=="Jan")
(mth=1)
endif
if (%2=="Feb")
(mth=2)
endif
if (%2=="Mar")
(mth=3)
endif
if (%2=="Apr")
(mth=4)
endif
if (%2=="May")
(mth=5)
endif
if (%2=="Jun")
(mth=6)
endif
if (%2=="Jul")
(mth=7)
endif
if (%2=="Aug")
(mth=8)
endif
if (%2=="Sep")
(mth=9)
endif
if (%2=="Oct")
(mth=10)
endif
if (%2=="Nov")
(mth=11)
endif
if (%2=="Dec")
(mth=12)
endif
if (%2=="Jan ")
(mth=1)
endif
if (%2=="Feb ")
(mth=2)
endif
if (%2=="Mar ")
(mth=3)
endif
if (%2=="Apr ")
(mth=4)
endif
if (%2=="May ")
(mth=5)
endif
if (%2=="Jun ")
(mth=6)
endif
if (%2=="Jul ")
(mth=7)
endif
if (%2=="Aug ")
(mth=8)
endif
if (%2=="Sep ")
(mth=9)
endif
if (%2=="Oct ")
(mth=10)
endif
if (%2=="Nov ")
(mth=11)
endif
if (%2=="Dec ")
(mth=12)
endif
(yea=%5)
(dat=%3)
jump 進入正軌
%bc 時間
break:0.34:%b%*不標準時間: %$ %$ %# %* %#
break:0.34:%b%*不標準時間: %$ %$ %# %* %#
%scene 死了
(hbf=0)
(siwang=siwang+1)
(diex=%1)
(diey=%2)
6::
(way=1)
do(true)
3:傳送:%vway
enddo
if (%m>50 && hbf==0)
loop20
0.4:hs:cast retime on
if (hbf==1)
break
endif
endloop
loop10
0.4:hstb:time_blink
endloop
endif
if ($vmap=="初始值")
call 使用位置
endif
log 在%vmap的%vdiex,%vdiey死了
(mudi=$vmap)
(map=1)
call 記錄位置
call 跑到目的
(o=diex)
(p=diey)
call 模糊走
loop3
1:撿屍體:get ALL_ITEM_IN %vzuo
endloop
call 看保護令
call 穿衣服
jump 我是要打錢↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。
对照原资料
查看 1 份来源与保存记录
台湾渔夫资料站
ikok大法无限打钱id通用全服第一稳定打钱_自动送钱_智慧设定负重,找柜台视野边缘_全模组化-老王感谢kk版本
查看保存记录
- 来源编号
k15- 资料集
- ikok代码
- 保存时间
- 2026-09-07
- 原始位置
- ikok大法无限打钱id通用全服第一稳定打钱_自动送钱_智能设置负重,找柜台视野边缘_全模块化-老王感谢kk版本.txt