本篇收录 3 节7,492 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 核对首坑、横竖方向、坑数、城名、定位与96,64银行；横转竖不代表所有固定坐标自动适配。
- 按是否学会独立吸魂、吸魂法术、暗夜幽魂设置开关；白名单只限制大臣任命，未限制所有远程口令。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
以黑火清怪、独立吸魂补MP，支持横坑或竖坑及两至五坑轮转，拾取后出售存款。
- 默认gta城，首坑21,64、ks=5、kfx=1横向18格间隔；竖坑用36格间隔，sfe=6,38，基础负重35，一轮rtm=385秒。
- 按当前位置找当前或下一坑；两至四坑用consider等刷新，五坑沿轮转；黑火最多五次，视野仍多于四只时reboot 8。
- MP缺口>800且soulsteal=1时用独立吸魂；精神过差改cast soul_steal。pmp默认0，暗夜回蓝支线关闭，darksoul也默认0。
- 先捡九个近点，再贪心安排附近尸体，超过基础负重出售；捡地上金币，回96,64存款，缺HP>100买膏药。
- mnswch开启后按小时分组延迟放火：第二组0.5秒、第三组实际0.8秒；dist另开测距。6:59回安全点待重启。
- 死亡按乌鲁路线取10000买保护；dai加入协作队员，kai驱逐，dachen仅对白名单任命。
02这份代码的适用限制
03完整代码
624 行原文
#原始作者小混混
#5月9日，加入分時段決定入坑停留時間放火，變數 time1 立即放火，time2 等待 0.5 秒，time3 等待 0.8 秒，填入24小時制的小時數字在相應變數裡
#5月12日，加入坑數上限變數 ks，最少 2 坑，最多 5 坑
#5月12日，加入橫豎坑變數 kfx
%var party
#白名單
troubadour
%var white
hoko
hokk
hok
okok
berserker
superman
superwoman
man
archmage
xiemo
shengzhe
demongod
popelord
oiio
l1ch
anqi
#第一坑坑心座標 X
%var ax
21
#第一坑坑心座標 Y
%var ay
64
#要打的坑數
%var ks
5
#橫坑為 1，豎坑為 2
%var kfx
1
#安全點
%var sfe
6,38
#每坑最右上NPC相對座標
%var npos
(0,0)
#NPC 通用 ID
%var npc
npc
#有沒有二階，1 是有
%var darksoul
0
#進坑前回藍，1 是要
%var pmp
0
#虧藍量
%var lmp
800
#坑裡吸魂，1 是會
%var soulsteal
1
#負重
%var heft
35
#扛打0，不扛1
%var risk
0
#錢裝 ID
%var zb
two_hand_axe
cloak
vest
boots
#城 ID
%var city
gta
#一輪預計時長
%var rtm
385
%var rpos
(5,5)
(5,16)
#身周八個方位相對座標
%var sur
(5,10)
(5,8)
(5,9)
(6,10)
(5,11)
(5,12)
(4,11)
(4,10)
(4,9)
#進坑等待總開關
%var mnswch
0
#測距開關
%var dist
0
#進坑等待時段，不等待
%var time1
0
1
2
3
9
12
15
22
#進坑等待時段，等待 0.5 秒
%var time2
4
5
6
14
17
20
21
#進坑等待時段，等待 1 秒
%var time3
7
8
10
11
13
16
18
19
23
%scene begin
toreal %vsfe (5,10) safe
if (%map != city)
do (true)
1:保護:look protection order
enddo
jump 回定位點
endif
if (kfx == 1)
if (%sx < ax - 9)
(rpos = (ax-11)*65536+ay)
run %vrpos 30
jump 回藍準備
endif
if (%sx > ax - 9 && %sx < ax + 9)
(a = ax * 65536 + ay)
endif
if (%sx > ax + 9 && %sx < ax + 27)
(a = (ax + 18) * 65536 + ay )
endif
if (%sx > ax + 27 && %sx < ax + 45)
(a = (ax + 36) * 65536 + ay)
endif
if (%sx > ax + 45 && %sx < ax + 63)
(a = (ax + 54) * 65536 + ay)
endif
if (%sx > ax + 63)
(a = (ax + 72) * 65536 + ay)
endif
endif
if (kfx == 2)
if (%sy < ay - 18)
jump 回藍準備
endif
if (%sy > ay - 18 && %sy < ay + 18)
(a = ax * 65536 + ay)
endif
if (%sy > ay + 18 && %sy < ay + 54)
(a = ax * 65536 + ay + 36 )
endif
if (%sy > ay + 54 && %sy < ay + 90)
(a = ax * 65536 + ay + 72)
endif
if (%sy > ay + 90 && %sy < ay + 126)
(a = ax * 65536 + ay + 108)
endif
if (%sy > ay + 126)
(a = ax * 65536 + ay + 144)
endif
endif
run %va 5
#當前經驗記錄為 exp
(exp = %e)
call 清怪
loop10
1:護體_bc:look
endloop
#if (%e > %vexp)
call 撿屍體
#endif
jump 回藍準備
%scene 回藍準備
do (%M - %m > lmp && pmp == 1)
if (%m < lmp)
call 冥想
endif
if (darksoul == 1)
5:暗夜:cast dark_soul
do (true)
0.5:吸魂:soul_steal (5,12)
enddo
2:鏢暗夜:kill (5,12)
endif
enddo
jump 跑下一坑
%scene 跑下一坑
if (kfx == 1)
if (%sx < ax - 9)
(a = ax * 65536 + ay)
endif
if (%sx > ax - 9 && %sx < ax + 9)
(a = (ax + 18) * 65536 + ay )
endif
if (%sx > ax + 9 && %sx < ax + 27)
if (ks == 2)
jump 回定位點
endif
(a = (ax + 36) * 65536 + ay)
endif
if (%sx > ax + 27 && %sx < ax + 45)
if (ks == 3)
jump 回定位點
endif
(a = (ax + 54) * 65536 + ay)
endif
if (%sx > ax + 45 && %sx < ax + 63)
if (ks == 4)
jump 回定位點
endif
(a = (ax + 72) * 65536 + ay)
endif
if (%sx > ax + 63)
jump 回定位點
endif
endif
if (kfx == 2)
if (%sy < ay - 18)
(a = ax * 65536 + ay)
endif
if (%sy > ay - 18 && %sy < ay + 18)
(a = ax * 65536 + ay + 36 )
endif
if (%sy > ay + 18 && %sy < ay + 54)
if (ks == 2)
jump 回定位點
endif
(a = ax * 65536 + ay + 72)
endif
if (%sy > ay + 54 && %sy < ay + 90)
if (ks == 3)
jump 回定位點
endif
(a = ax * 65536 + ay + 108)
endif
if (%sy > ay + 90 && %sy < ay + 126)
if (ks == 4)
jump 回定位點
endif
(a = ax * 65536 + ay + 144)
endif
if (%sy > ay + 126)
jump 回定位點
endif
endif
call 查下一坑重新整理
%scene 回定位點
run 96,64 2
(tf = %now - tst)
(gf = %g - gst)
(estr = 86390/tf)
(estg = estr * gf)
log 第 %irnd 輪用時 %vtf 秒，收穫金幣 %vgf 枚。預計今日可打 %vestr 輪 %vestg 枚金幣。
show ----- 第 %vrnd 輪用時 %vtf 秒，收穫金幣 %vgf 枚。預計今日可打 %vestr 輪 %vestg 枚金幣。 -----
if (%g > 0)
0.3::@&click 銀行櫃檯
0.3::deposit %g
endif
if (%H - %h > 100)
call 貼膏藥
endif
if (tf < rtm)
(wt = rtm - tf)
do (wt > 0)
1::%dwt
show ----- 還有 %vwt 秒開始下一輪 -----
enddo
endif
do (%map != city || %sc != safe)
10:定位:cast location on me
enddo
0.3::@&click 銀行櫃檯
0.3::deposit %g
if (risk == 0)
(tst = %now)
(gst = %g)
call 清怪
call 撿屍體
jump 跑下一坑
endif
jump 回藍準備
%scene 貼膏藥
do (%g < 500)
0.3::@&click 銀行櫃檯
0.3::withdraw 500
enddo
0.3::@&click 草藥店櫃檯
0.3::buy 1 plaster
0.3::apply plaster
return
%scene 傳送回城
do (true)
10:定位:home me
enddo
loop10
2:定位:cast location
endloop
return
%scene 查下一坑重新整理
if (%m < lmp)
call 回藍
endif
toreal %va npos nrpos
if (ks <= 4)
loop100
1:consider_bc:consider %vnrpos
endloop
endif
if (%sx < ax -9)
(tst = %now)
(gst = %g)
endif
run %va 20
if (mnswch == 1)
call 查時段
endif
if (dist == 1)
call 測距
endif
call 清怪
call 撿屍體
jump 跑下一坑
%scene 測距
if (%hh in time1)
(stp = 2)
endif
if (%hh in time2)
(stp = 2)
endif
if (%hh in time3)
(stp = 1)
endif
loop100
loadmapvar %vnpc npcpos
foreach npcpos
(nsx = npcpos/65536)
if (nsx > %sx - stp && nsx < %sx + stp)
clearmapvar %vnpc
return
endif
loop
clearmapvar %vnpc
endloop
return
%scene 清怪
do (soulsteal == 1 && %M - %m > lmp)
0.3:吸魂:soul_steal
if (%m < 150)
wait3
reboot 5
endif
enddo
loop3
loadmapvar %vnpc npcpos
foreach npcpos
(npcx = npcpos/65536)
(npcy = npcpos - (npcx*65536))
if (npcy > %sy + 8 || npcy < %sy - 8)
0.3::kill %vnpcpos
endif
remove npcpos %vnpcpos
loop
if ($lnpcpos == 0)
break
endif
endloop
clearmapvar %vnpc
loadmapvar %vparty wait
if ($lwait > 0)
25:wait_bc:sing 鏢完 sing 鏢完
endif
clearmapvar %vparty
loop5
loadmapvar %vnpc npcpos
if ($lnpcpos == 0)
break
endif
2:闇火:cast black_flame
if (%m < 150)
reboot 5
endif
endloop
clearmapvar %vnpc
loadmapvar %vnpc npcpos
show ---------------- 檢測到還有 %lnpcpos 個NPC在螢幕內 ----------------
if ($lnpcpos > 4)
reboot 8
endif
clearmapvar %vnpc
return
%scene 闇火
loop5
loadmapvar %vnpc npcpos
if ($lnpcpos == 0)
break
endif
2:闇火:cast black_flame
endloop
clearmapvar %vnpc
return
%scene 撿屍體
0.34::@&click 櫃檯
do(%heft > heft)
0.24:賣裝:sell 2
0.24:賣裝:sell 1
enddo
loadmapvar gold goldpos
loadmapvar corpse c
foreach c
(poscx = c/65536)
(poscy = c - (poscx*65536))
if (poscx > %sx + 3 || poscx < %sx - 3 || poscy > %sy + 6 || poscy < %sy - 6)
remove c %vc
endif
loop
(crps = 28 - $lc)
show ------ 這坑放棄 %vcrps 個屍體 -----
toreal %sc sur w
foreach w
if (%vw in c)
remove c %vw
loop3
1:撿取:get ALL_ITEM_IN %vw
endloop
show ------這坑你已經撿了%in套裝備了------
do (%heft > heft)
0.2:賣裝:sell 1
enddo
endif
loop
greedy c t
foreach t
run %vt 10
loadround c s
foreach s
remove c %vs
loop3
1:撿取:get ALL_ITEM_IN %vs
endloop
show ------這坑你已經撿了%in套裝備了------
do (%heft > heft)
0.2:賣裝:sell 1
enddo
loop
loop
::%zn
clearmapvar corpse
foreach goldpos
run %vgoldpos 10
1:撿取:get
loop
clearmapvar gold
if (%hh == 6 && %mm >= 59)
do(%sc != safe)
2:傳送:home me
enddo
(rbt = 25330-(%hh*3600+%mm*60))
reboot %vrbt
endif
return
%scene 回藍
do (%m < 500 && pmp == 1)
if (%m < 300)
call 冥想
endif
5:暗夜:cast dark_soul
do(true)
0.5:吸魂:soul_steal (5,12)
enddo
2:鏢暗夜:kill (5,12)
enddo
return
%scene 買藥喝
0.5::@&click 銀行櫃檯
0.5::withdraw 5000
0.5::@&click 草藥店櫃檯
0.5::buy 10 yellow potion
loop10
0.5::drink potion
endloop
0.5::@&click 銀行櫃檯
0.5::deposit %g
return
%scene 查時段
if (%hh in time2)
0.5::say 等待 0.5 秒後放火
endif
if (%hh in time3)
0.8::say 等待0.8 秒後放火
endif
return
%scene 左右跑
toreal %va rpos rtpos
run %vrtops 4
::%irtops
run %vrtops 4
run %va 4
return
%scene 復活
priority
do (%map != "kaies")
2::recall 1
endloop
run 364,696 50
do (%g < 5000)
0.5::look 1@23528127
0.5::withdraw 10000
enddo
do (%g>5000)
0.5::look 2@24117945
0.5::buy_protect
1:保護:look protection order
enddo
show 死亡%iq次
jump 回定位點
%scene 開人
0.3::banish %1
return
%scene 大臣
if (%1 in white)
0.5::appiont CONFIRM %1
endif
return
%scene party
add party %1
show ----- 隊員 %vparty ---------
0.5::party form
0.5::party invite %1
return
%bc 保護
jump:復活:你要看什麼 ?
break::烏魯市政廳釋出的保護令，是一張上面記%*
%scene 冥想
20:冥想:meditate
return
%scene 吸魂術
3:吸魂術:cast soul_steal on (5,12)
return
%bc 定位
call:闇火:你正%*
retry:1:你上%*
retry:1:但是%*
break::你把你的「念」留在這裡了。
break::你進入區域%*
break::你在原地跳了跳。
call:傳送回城:你並未記憶定位點。
call:傳送回城:你不能在這裡施法。
call:傳送回城:你的法力不夠了 ...
%bc 暗夜
call:冥想:你的法力不夠 !!
retry:0.5:但是%*
retry:0.5:你上%*
retry:0.5:你正%*
next::%*開始跟蹤你。
%bc 吸魂術
retry:0.5:但是%*
retry:0.5:你上%*
retry:0.5:你正%*
call:冥想:你需要有目標!
call:冥想:沒有這個目標!
call:冥想:你的法力不夠 !!
%bc 吸魂
call:吸魂術:你的精神狀況太差, 沒有辦法使用吸魂術 ...
break::你需要有目標!
break::沒有這個目標!
break::無法攻擊到他！
break::%*已經沒有精神力可供你吸取了 ...
%bc 鏢暗夜
retry:0.5:你上%*
retry:0.5:你正%*
next::你喝道 :「%*
%bc 護體_bc
break::你放出你的%*。
retry::籠罩在你身上的%*
call:冥想:你的法力不夠了 ...
%bc 冥想
call:買藥喝:你現在身體狀況太差了﹐無法集中精神 !
retry::你正%*
retry::你上%*
call:闇火:戰鬥中無法冥思 !
next::你的精神還沒有恢復%*
next::你深深地吸了一口氣，從深沈的冥思中醒來 !
%bc consider_bc
break:0.5:你用挑釁的眼光上下打量%*
%bc 闇火
break::你現在不在戰鬥中。
break::你要有目標才能施法。
break::你需要有目標!
#break::沒有這個目標!
%bc 戰鬥判斷
break::沒有這個地方。
%bc 傳送
break::你進入區域%*
break::你在原地跳了跳。
call:闇火:你現在正在戰鬥中%*
%bc 撿取
retry:0.5:你正在移動中
break::你撿起%*
%bc 賣裝
break::你無法與你視線範圍外的商店進行交易 ...
break::what ?
break::你不能把這個東西賣掉 !
%bc wait_bc
next::%*)高興地唱著：鏢完 ...。
%public_bc
jump:復活:慢慢地你終於又有了知%*
call:開人:%b【%*(%*)﹕kai
call:開人:%b【%*(%*)kai
call:大臣:%b%*(%*)告訴你 : dachen
call:party:%b%*(%*)告訴你 : dai↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。