本篇收录 3 节1,744 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 负重能拿至少一具尸体的全部掉落，原建议只留虚空钱包。
- 10尸体门槛须大于主号第一时风会杀死的数量，原文建议必要时改15或18。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
每坑一小号，以nick中的坐标为等待点，观察尸体数后进中心拾卖并存款。
- nick设中心上一步，如6,64坑设6,62，run %K到位，负重>5先清理物品。
- 等尸体数至少10；若不足28则等5秒向南一步再读尸体，进入拾取。
- greedy规划路线，负重>9时sell 1，离商店太远回nick位置重试。
- 清尸体缓存、点银行存入身上金币；拿不动回原点按5负重阈值清理。
02这份代码的适用限制
03完整代码
86 行原文
#相關要求：每一個撿錢小號預設站立位置為其管理的錢坑中心點向上一格，並將其nick設定為該地址。比如坑中心點為6,64，那麼該坑撿錢小號的nick需要設定為nick 6,62
#一坑一個小號，負責整個坑，負重需要能夠至少撿起一個屍體。同時建議身上除了虛空錢包外其他什麼東西都沒有（即負重為0）
#其餘說明順著代碼看即可，看完後可ctrl+f搜尋 # 號，將備註全部刪掉，以整潔代碼
%scene begin
run %K
#跑向自己nick上對應的那個位置碼
loop3
1:click_bc:@&click 櫃檯
endloop
do(%heft>5)
0.34::sell 1
0.34::sell 2
0.34::sell 3
enddo
#上線後檢測身上是否有之前遺留的物件，如果有的話就迴圈賣掉。
do($lc<10)
loadmapvar corpse c
run %K
show %lc
enddo
#因為撿錢小號初始不會站在坑中心，因此它不可能檢測的到28個屍體位置，這裡設定屍體位置記錄到%var c之中，預設當小號檢測到場面上有超過10個屍體出現，那麼就認為大法已經清掉了全屏（即大法一定不能第一個時風就殺掉10個以上的NPC，如果不能保證這點，就把10這個數字再放大一些，比如15、18之類的）
if($lc!=28)
5::
0.34::go s
loadmapvar corpse c
show %lc
endif
show %lc
#這裡就是在檢測到上面出現了10個屍體資訊後，如果目前記錄到的屍體資訊不為28個，則在等待5秒後（加入這個5秒的等待，是為了等大法那邊殺完全屏後走人，讓出坑中心點位），向南走一格（即走到了坑中心點），再次讀取全屏的屍體資訊（因為大法代碼的機制以及本小號的機制，站在這個點的時候讀取全屏屍體數量資訊，一定能夠讀到28個），之後進入撿賣模組
call sell
#進入撿賣模組
clearmapvar corpse
#清除屍體位置資訊
0.34::@&click 銀行櫃檯
0.34::deposit %g
%scene sell
loop3
1:click_bc:@&click 櫃檯
endloop
10::
greedy c t
foreach t
run %vt 8
loadround c s
foreach s
remove c %vs
3:get_bc:get ALL_ITEM_IN %vs
do(%heft>9)
0.34:sell_bc:sell 1
enddo
run %vt 8
loop
loop
return
#標準的貪心演算法
%scene center
1::run %K
return retry
#加入了為撿邊緣屍體導致離開了裝備店範圍，需要稍微返回一點點坑中心位置再繼續賣裝備的機制
%bc click_bc
break:0.34:這是一張生意場所經常使用來記帳的櫃檯。
%bc get_bc
retry:0.34:你現在不能拿這具屍體%*
retry:0.34:你上一個動作還沒有完成 !
retry:0.34:你上一個動作沒有%*
next:0.34:這裡沒有任何東%*
next:0.34:你撿起%*
%bc sell_bc
break:0.34:你不能把這個東西賣%*
break:0.34:what ?
call:center:你無法與你視線範圍外的商店進行交易 ...
%public_bc
next:0.34:你要往哪個方向 ?
call:drop:你拿不動了 !
%scene drop
run %K
loop3
1:click_bc:@&click 櫃檯
endloop
do(%heft>5)
0.34::sell 1
0.34::sell 2
0.34::sell 3
enddo
return
#在拿不動的狀態下選擇回到坑內設定點位進行銷售，而不是扔在地上浪費錢↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。