本篇收录 3 节4,184 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 作者测试样本：44级、时风100、回时100、时跳93、智慧90、毅力90、MP2697，对53级MOB；这是该样本表现。
- 各城坑位一致、MOB统一sugar前缀，一坑一拾取小号；建议柜台(5,4)、银行(5,2)。
- 替换写死的sugar及保护令8800费用，要求回时、时跳、时风、吸魂、电击、双施与定位。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
三城相同五坑布局，利用吸魂带时风、电击带吸魂，再关闭双施补第二个时风，由独立小号拾取。
- locate 1、2、3依次到各城第一坑，home第一城第一坑，a为6/24/42/60/78,64。
- 关闭双施给自己回时，必要时call时跳；等sugar目标数量等于28。
- 开双施、自动时风，吸魂sugar c带出第一时风；改自动吸魂，用stun控场带出吸魂。
- 关闭双施→时跳→第二时风→时跳，等待尸体数恰好28才换坑。
- 死亡或无法进入位置时去乌鲁取8800、买保护令、回home，MP到八成后重新开始。
02这份代码的适用限制
03完整代码
182 行原文
#測試場景：大法44級，時風100，回時100，時跳93，智慧90，毅力90，MP2697
#在此場景下，打3城一輪NPC全部正好重新整理，不浪費NPC資源且大法全程保持滿MP
#錢坑NPC為53級，兩個時風炸乾淨全屏的方案，第一個時風有可能會炸死1~2個NPC，第二個時風一定可以清場
#相關設定：三座城大法定位（locate）均需在第一坑，並且請home me定位在第一座城的第一坑中心點。
#三座城的坑位需要一致。每一坑配置1名撿屍小號，建議坑內相對位置（5,4）有櫃檯，相對位置(5,2）有銀行
#錢坑npc的id如果不是sugar+ABCD...這個代碼造的話，那請ctrl+f搜尋sugar，並將對應位置的npc id替換為你坑內NPC的ID即可。這裡我沒有使用%var來方便改動，主要是擔心產生BUG
#其餘說明順著代碼看即可，看完後可ctrl+f搜尋 # 號，將備註全部刪掉，以整潔代碼
%var a
6,64
24,64
42,64
60,64
78,64
#var a 內填入你的坑中心位置
%var loc
1
2
3
#locate定位3個，均為每座城的第一坑中心
%scene begin
if(%map=="skara"||%map=="kaies")
5:home_bc:home me
endif
jump start
#本段意思為，賬號登入時如果因為之前伺服器重啟、人物死亡恰逢伺服器重啟、掉線等狀況導致跑去了系統區烏魯或者史坎佈雷，則嘗試先home me回到第一城錢坑的第一坑位置
%bc home_bc
retry:1:你正忙著呢 !
retry:1:你剛剛才轉換過區域，請稍待一會兒再試 !
next:0.34:你進入區域%*
next:0.34:你在原地跳了跳。
%scene start
10:say_bc:say hello world
jump revive
#IKOK的靈魂，先向世界問個好，同時利用該機制檢查自己是否身處系統區，不在系統區（即在錢坑內）則正常開始打坑跑坑，否則說明自己可能剛死過，進入系統區跑路段落
%bc say_bc
jump:run:你說道﹕hello world
jump:run:在%*及時空魔法%*
%scene run
0.4::set two_magic 0
#關閉雙重法術，防止給自己回時時候觸發了時風
call buff
#調取給自己加回時的段落
20:locate_bc:locate %vloc
::%iloc
#按順序傳送至第1、2、3國的第一個錢坑中心
loop20
1:check_bc:jump
endloop
#防止系統卡頓導致傳送後沒有指令返回，用表情跳躍來檢測伺服器傳輸是否卡頓
foreach a
run %va 20
#跑坑
call buff
#調取給自己加回時的段落
do($lkeng!=28)
loadmapvar sugar keng
enddo
#檢測坑內28個NPC是否已全部復活並將其數量記錄到%var keng中，如果數量不等於28，則說明目前坑內沒有28個NPC，那麼代碼將在這裡做等待，一直等待其全部復活後再繼續進行（作用相當於過去的consider檢測方案，但這個命令不需要和伺服器做指令互動且可以直接檢測全屏NPC數量，因此更加好用）
call kill
#若全部復活，則調取擊殺模組
clearmapvar sugar
#清除id為sugar的所有NPC位置資訊，沒啥用，謹慎起見加進來，反正不佔時間，都是IKOK內部運算
do($lshiti!=28)
loadmapvar corpse shiti
show %lshiti
enddo
#因上方已經調取了擊殺NPC的模組，代碼走到這裡預設已經全部擊殺了，所以用DO這個命令來確認這28個NPC是否已經死成屍體（corpse）了，之後再進行下一步（相當於過去檢測敵人是否已經死完了而用recall 愛的小屋之類的來檢測自己是否脫戰的機制一樣，本方案更加好用）
foreach keng
remove keng %vkeng
loop
#走到這裡說明這一坑的確確實實死完了，那麼就將其數量資訊清除乾淨，從而不影響對下一坑的判斷
foreach shiti
remove shiti %vshiti
loop
show %lshiti
#和上面一條一樣，但這一條是用於清除本坑記錄的屍體數量資訊
loop
%scene buff
0.34::
10:buff_bc:cast retime on
return
#簡單的調取回時的段落
%bc buff_bc
retry:0.34:你正忙著呢%*
retry:0.34:你上一個動作沒有%*
call:tbk:你低頭凝神念著某個時空禁咒%*
next:0.34:回時術的力量依然在你的身上作%*
%scene tbk
0.34::
2:timeblink_bc:time_blink
return
#buff段給自己加回時，如果身上已經有回時了，就不會CALL到這個時跳段落，從而節省時間。
%scene kill
0.4::set two_magic 1
0.4::set spell time_storm
7:cast_bc:cast soul_steal on sugar c
#KILL擊殺NPC段落，這裡開啟雙重法術，並將自動法術設定為時風，對坑內id為sugar c的這個NPC進行吸魂並且帶出時風，這樣可以在不浪費任何時間的前提下同時提升大法的續航
0.34::set spell soul_steal
do(true)
4:stun_bc:cast stun on sugar
enddo
#這裡再將自動法術改為吸魂，並在第一個時風炸過後對全屏NPC進行1次電擊定身，同時繼續用自動法術吸隨機（一般來說系統會預設為最右下角的那個）一名NPC的魂，在不浪費時間的前提下進一步提升大法的續航
0.34::set two_magic 0
2:timeblink_bc:time_blink
7:cast_bc:cast time_storm
2:timeblink_bc:time_blink
return
#所以整個戰鬥流程就是：吸魂1名NPC+自動帶出時風，電擊全屏被炸到的NPC（電擊前不做時跳，這樣NPC剛好近身）同時吸魂隨機一個NPC，關閉雙施節省法術（因為你第二次時風炸下來後再吸魂會吸不到NPC且浪費一次吸魂的MP），電擊帶出的吸魂後時跳，第二個時風，時跳，全屏打完，進入主段落的檢測是否全屏死乾淨了
%bc cast_bc
retry:0.34:你正忙著%*
retry:0.34:你上一個動作沒有%*
next:0.34:你的雙手間漸漸形成藍色亮光%*
%bc stun_bc
retry:0.5:你正忙著%*
retry:0.5:你上一個動作沒有%*
break:0.5:你在你和%*
break:0.34:你現在不在戰鬥中。
%bc locate_bc
retry:0.34:你上一個動作沒有%*
retry:2:你剛剛才轉換過區域，請稍待一會兒再試 !
retry:2:你才使用傳送不久，沒辦法這麼快再用。
next:1:你進入區域%*
retry:0.34:你正忙著呢 !
%bc timeblink_bc
retry:0.34:你試圖擾動時空能流%*
retry:0.34:你才剛擾動過時空%*
next:0.34:你的身體突然由內向外放出光芒%*
next:0.34:你現在並不忙%*
%bc recall_bc
retry:0.34:你上一個動作沒有%*
retry:3:你剛剛才轉換過區域%*
break:0.34:你祈求神把你帶回%*
%public_bc
log::你死了。
next:0.34:你要往哪個方向 ?
jump:revive:慢慢地你終於又有了知%*
jump:revive:你要去的位置無法進入, 請稍後使用指令輸入視窗中%*
#下面這段就是從臺服起就一直在用的死亡後自動跑烏魯買魂魄保護券的段落，唯一要注意的一點是我這個44級的大法買一次卷軸的價格是8800，所以下方寫的是8800，使用者可根據自身情況做調整
%scene revive
priority
wait1
loop20
10:recall_bc:recall 1
endloop
loop20
1:restore1_bc:cast retime on
endloop
2:timeblink_bc:time_blink
run 343,649 5
run 360,693 23
1::@&click 銀行
1::withdraw 8800
if (%g<8800)
jump revive
endif
run 364,690 5
loop5
1:protect_bc:look 2@24117945
endloop
0.5::buy_protect
0.5::set two_magic 0
5:home_bc:home me
loop20
1:check_bc:jump
endloop
do(true)
5:restore_bc:cast retime on
enddo
jump start
%bc protect_bc
break:0.34:%*是市長的雙生弟弟，喜歡和哥哥穿一樣%*
%bc restore_bc
break:0.34:%m>=0.8*%M
retry:0.34:你上一個動作沒有完成, 不能施法!
next:1.5:回時術的力量依然在你的身上作用著。
%bc restore1_bc
break:0.34:你低頭凝神念著某個時空禁咒的古咒語 ...
next:0.34:你上一個動作沒有完成, 不能施法!
break:1.5:回時術的力量依然在你的身上作用著。
%bc check_bc
break:0.34:你高興地像小孩子似的蹦蹦跳跳。
break:0.34:在%*及時空魔法%*↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。