本篇收录 3 节7,120 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 需妖术风龙、灵鞭、鉴定及本国制造权限，能看到所有魔力炉、铁匠／防具铺并捡到产物；右15格留合格品。
- 武器与防具的制造起始等级不同，作者建议分开批次；c用制造部位ID，不是产物默认ID，armor/t及中英文命名表须按原顺序对应。
- 明确k、l下限在前上限在后；d材质列表包含重复轮次，按原顺序保留。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
老王2022年4月4日的多炉程序，逐炉制造并累计灌入3000 MP，再按技能／等级和附加属性筛选，保留合格件、删除其余自制物品。
- 站16,19，c默认dagger、制造等级e=50；加载视野内furnace逐炉制造，武器make 部位 等级、防具另带d材质。
- 保证风龙目标，MP不足时冥思、灵鞭吸魔，load 1后反复charge furnace，累加每次灌入前MP到3000，炉占用时尝试下一炉。
- 处理完一轮炉子后杀掉风龙、查地上新物品，按实际位置接近拾取，do_identify 1读取属性。
- 武器要求技能240～248，防具等级24～45，且附加属性在m列表中；默认只接受敏捷5。n列表是备用属性，未自动纳入。
- 合格件移动到站位右边x+15，按预设中英文名和ID改名、落地并发城邦消息，然后递增制造部位；防具部位完成再递增材质，遇“结束”stop。
- 不合格件按启动负重基准用delete_item 1回收，随后回到原工位。
02这份代码的适用限制
03完整代码
629 行原文
#老王來全自動灌爐2022-4-4 19:53:21
#可以n個爐子一起灌呢,麼麼噠.為什麼國家不能有20個魔力爐啊.
#職業要是妖術.
#灌爐物品主要是c變數,防具和武器初始製造等級大多不一樣.為防止搞不清,武器和防具能分開灌就分開灌.c變數遇到合格件就會遞增,遞增結束,如果是防具,防具材質才會遞增.一旦防具材質var d 遞增到了 結束 ,就停機
#灌爐站位,能看到所有爐子和鐵匠鋪和防具鋪,出了好裝備要能撿到,有好裝備丟在能往右跑x+15座標
%var a
16,19
#製造的部位,可以多個,達到合格的就會增加,注意要是製造的id,不是物品的預設id,參考var armor和var weapon 這兩個變數的英文
%var c
dagger
#防具材質，從第一個變數開始,按順序,c變數有合格件都到底了,就增加材質往下,灌到 結束 就停
%var d
布料
皮革
重金屬
金皮複合
布料
皮革
輕金屬
布皮填充
結束
#本次灌製物品的等級
%var e
50
#有用的武器技能,第一個是保留的最低技能,第二個最高技能,千萬不要搞混
%var k
240
248
#有用的防具等級,第一個是保留的最低等級,第二個最高等級,千萬不要搞混
%var l
24
45
#有用的屬性
%var m
敏捷 : 5
#備用的,可以把下面有用的屬性放到上面
%var n
毅力 : 5
敏捷 : 5
智慧 : 5
毅力 : 5
體質 : 5
運氣 : 5
力量 : 5
防禦力 : 11
額防 : 11
傷害力 : 11
武器等級 : 11
敏捷 : 4
毅力 : 4
智慧 : 4
毅力 : 4
體質 : 4
運氣 : 4
力量 : 4
敏捷 : 3
毅力 : 3
智慧 : 3
毅力 : 3
體質 : 3
運氣 : 3
力量 : 3
敏捷 : 2
毅力 : 2
智慧 : 2
毅力 : 2
體質 : 2
運氣 : 2
力量 : 2
敏捷 : 2
毅力 : 1
智慧 : 1
毅力 : 1
體質 : 1
運氣 : 1
力量 : 1
#防具中文,可以自定義名字,順序不能亂
%var fjzw
盾牌
手套
戒指
披風
鞋子
項鍊
頭盔
衣服
#防具英文,可以自定義名字,順序不能亂
%var fjyw
lwdp
lwst
lwjz
lwpf
lwxz
lwxl
lwtk
lwyf
#武器中文,可以自定義名字,順序不能亂
%var wqzw
匕首
雙手劍
單劍
棒
杖
飛鏢
弓
十字弓
槍
矛
雙手刀
單刀
雙手錘
單錘
雙手斧
單斧
#武器英文,可以自定義名字,順序不能亂
%var wqyw
lwbs
lwssj
lwdsj
lwbang
lwzhang
lwfb
lwgong
lwszg
lwqiang
lwmao
lwssd
lwdsd
lwssc
lwdsc
lwssf
lwdsf
#從本段開始往下，除了代碼高手以外，其他任何地方都不要改,後果自負
#吸魔物件。不要改
%var f
wind dragon
#不要動
%var armor
shield
gloves
ring
cloak
boots
misc
head
body
#不要動
%var t
shield
gloves
ring
cloak
boots
necklace
helmet
vest
#不要動
%var weapon
dagger
two_hand_sword
sword
wand
staff
dart
bow
crossbow
lance
spear
two_hand_blade
blade
two_hand_hammer
hammer
two_hand_axe
axe
%scene begin
(heavy=%heft)
do(true)
1:說話:sing 老王牌灌多個爐,質量頂呱呱
enddo
jump make
%scene make
#這裡啥也沒有
jump prepare
%scene 初次鑑定
0.5::cast identify
return next
%scene prepare
#這裡啥也沒有
jump charge
%bc 點爐子
break:0.4:你眼前的醜陋生物就是傳說中的%*
break:0.4:那裡沒有任何東西。
%bc 放東西
break:0.4:你把%*魔力爐中。
#靈鞭判斷
%bc whip_bc
call:下一個:數道異色的光線自%*
call:沒這個龍:那裡沒有任何人。
%scene 下一個
(u=1)
::%iwz
return next
%bc 輸入法力
break:0.4:你握緊魔力爐的觸手, 把所有的精神力輸送進去。
%bc 龍來了
next:0.4:風之幻龍開始跟蹤你。
%scene 沒這個龍
loadmapvar %vf wz
do($lwz<1)
do(%m<200)
1::meditate
enddo
loop5
0.5::cast wind_dragon
endloop
10:龍來了:
loadmapvar %vf wz
enddo
return next
%scene 準備藍
loadmapvar %vf wz
do($lwz<2)
do(%m<200)
1::meditate
enddo
loop5
0.5::cast wind_dragon
endloop
10:龍來了:
loadmapvar %vf wz
enddo
if(%m>%M-500)
return next
endif
do(%m<100)
1::meditate
enddo
if(%m<400)
(u=0)
do(u==0)
0.5:whip_bc:cast soul_whip on %vwz
enddo
call 解除忙碌
endif
return next
%scene 解除忙碌
do(true)
0.5:解除忙碌:recall 8
enddo
return next
%bc 解除忙碌
break:0.4:你祈求神把你帶回愛的小屋 ...
%bc 放入裝備
break:0.4:你把%*送入魔力爐中。
call:爐子佔用:現在魔力爐正在活動,你不能把東西放進去。
%scene 爐子佔用
::%is
do(true)
1:點爐子:look 1@%vs
enddo
return next
#灌爐核心
%scene charge
toreal %va (5,10) q
call 轉換座標
call 挪一步
loadmapvar furnace s
foreach s
(linshi=$os + 1)
do(true)
1:說話:sing 開始第 %vlinshi 個爐子,共有 %ls 個
enddo
toreal %va (5,10) q
call 轉換座標
call 小模糊走
if (%vc in armor)
1::@&click 防具鋪火爐
2::make %vc %vd %ve
endif
if (%vc in weapon)
1::@&click 打鐵火爐
2::make %vc %ve
endif
call 準備藍
do(true)
1:點爐子:look 1@%vs
enddo
(zong=0)
(fangle=0)
do(zong<3000)
if(fangle!=1)
do(true)
0.5:放入裝備:load 1
enddo
(fangle=1)
endif
(u=0)
do(u==0)
0.4:whip_bc:cast soul_whip on %vwz
enddo
(fali = %m)
do(%m>=fali)
1:輸入法力:charge furnace
enddo
(zong=zong+fali)
call 解除忙碌
enddo
do(true)
1:說話:sing 這個第 %vlinshi 個爐子 總共輸入了 %vzong 的法力
enddo
loop
do(true)
1:說話:sing %ls個爐子都完事了,我現在看一下地上出現的裝備
enddo
call echo
#出貨撿裝備
%scene echo
loadmapvar %vf wz
do($lwz!=0)
loadmapvar %vf wz
0.5::kill wind dragon
enddo
call 撿動作
return next
#鑑定
%scene identify
do(%m<100)
1::meditate
enddo
(u=0)
do(u==0)
3:identify_bc:do_identify 1
enddo
if(u!=2)
do(true)
1:說話:sing 這不是我想要的，回收
enddo
call 刪裝備
endif
return next
%bc 說話
break:0.4:你高興地唱著：%* ...。
#判斷武器取捨
%scene resultb
(u=1)
do(true)
1:說話:sing 武器 ^[32m %vc^[33m 技能%1 ^[34m屬性^[35m%3
enddo
(&k=0)
(xiaxian=$vk)
(&k=1)
(shangxian=$vk)
(linshi = %1)
if(linshi >= xiaxian && linshi <= shangxian)
do(true)
1:說話:sing 武器 ^[32m %vc^[33m 技能 %1 ^[34m達到了要求,再來看看屬性
enddo
if(%3 in m)
do(true)
1:說話:sing 武器 ^[32m %vc^[33m 技能 %1 ^[34m屬性 ^[35m%3 都達到了要求
enddo
call epic
endif
endif
return next
#判斷防具取捨
%scene result
(u=1)
do(true)
1:說話:sing 防具 ^[32m %vc^[33m 等級%1 ^[34m屬性^[35m%3
enddo
(&l=0)
(xiaxian=$vl)
(&l=1)
(shangxian=$vl)
(linshi = %1)
if(linshi >= xiaxian && linshi <= shangxian)
do(true)
1:說話:sing 防具 ^[32m %vc^[33m 等級 %vlinshi ^[34m達到了要求,再來看看屬性
enddo
if (%3 in m)
do(true)
1:說話:sing 防具 ^[32m %vc^[33m 等級 %vlinshi ^[34m屬性 ^[35m%3 都達到了要求
enddo
call epic
endif
endif
return next
%scene 刪裝備
do(%heft>heavy)
0.5:刪裝備:delete_item 1
enddo
(heavy=%heft)
return next
%bc 刪裝備
break::這件東西不是由你國家制造的。
%scene 轉換座標
(calit=q)
(o= calit / 65536)
(p= calit % 65536)
return next
%bc 告訴自己
break:1:%b%*(%$)告訴你 : 屬性%+ : %#嗯
%var dj
%var jn
#在站位右邊座標x+15位置丟下有用裝備，c部位、d材質
%scene epic
toreal %va (5,10) q
call 轉換座標
(o=o+15)
call 小模糊走
(dj=%1)
(jn=%1)
do(true)
3:告訴自己:tell %n 屬性%3嗯
enddo
(&wqzw = $oweapon)
(&wqyw = $oweapon)
(&fjzw = $oarmor)
(&fjyw = $oarmor)
if (%vc in armor)
1::set_item %vt prop name %vdj級^[33m%vd%vfjzw%2%3
1::set_item %vt prop id %vfjyw
endif
if (%vc in weapon)
1::set_item %vc prop name %vjn^[33m%vwqzw%2%3
1::set_item %vc prop id %vwqyw
endif
1::drop 0 1
if (%vc in weapon)
1::city 老王發來賀電 恭喜你 : 獲得 武器（ %vjn %vc 屬性是: %2 + %3），並且輕輕的放在 %vo,%vp
if($oc + 1 == $lc)
1::city 已經完成所有的武器製作了,我現在停下來了
endif
endif
if (%vc in armor)
1::city 老王發來賀電 恭喜你 : 獲得 防具（ %vdj 級 %vd %vfjzw 屬性是: %2 + %3），並且輕輕的放在 %vo,%vp
if($oc + 1 == $lc)
::%id
if($vd=="結束")
1::city 所有的防具材質都完成了,我現在停下來了
stop
endif
endif
endif
::%ic
(u=2)
return next
%bc get_bc
break:0.34:這裡沒有任何容器。
break:0.34:你的附近沒有這種東西。
break:0.34:這裡沒有任何東%*
break:0.4:%*體裡面沒有任何東西。
break:0.4:%*骨裡面沒有任何東西。
break:0.4:%iu你撿起%*
call:全撿:%*裡面有這些東西%*
break::%iu你現在不能拿這具屍體的東西。
%scene 返回
return next
#鑑定防具判斷
%bc identify_bc
jump:返回:你低頭對著錢包%*
call:result:%b%*使用等級 : %# 製造地 : %*附加值 : %*
call:resultb:%b%*需要技能 : %# 最大傷害力%*附加值 : %*
break:0.4:%*你要鑑定哪一件東西 ?%*
call:初次鑑定:what ?
%bc epic_bc
call:helmet:show head
call:vest:show body
call:necklace:show misc
%scene helmet
(c = "helmet")
return
%scene vest
(c = "vest")
return
%scene necklace
(c = "necklace")
return
%bc dfire_bc
retry::你的妖火向四周漸漸散去消失了。
%scene 撿動作
if (%vc in armor)
foreach armor
if($vc == $varmor)
(&t=$oarmor)
break
endif
loop
else
(t=$vc)
endif
loadmapvar %vt wz
show %vwz
if ($lwz != 0 )
foreach wz
(q=wz)
call 轉換座標
call 小模糊走
call 挪一步
(u=0)
call 撿四方
call identify
call 刪裝備
loop
endif
loop
toreal %va (5,10) q
call 轉換座標
call 模糊走
return next
%scene 小模糊走
do (%sx > o+1 || %sx < o-1 || %sy > p+2 || %sy < p-2)
1::@&run %vo,%vp
enddo
loop3
if (%sx == o && %sy == p)
break
endif
0.4::@&run %vo,%vp
endloop
return next
%scene 模糊走
do (%sx > o+3 || %sx < o-3 || %sy > p+6 || %sy < p-6)
1::@&run %vo,%vp
loop6
if (%sx == o && %sy == p)
break
endif
0.4::@&run %vo,%vp
endloop
return next
%scene 挪一步
loop3
if (%sx == o && %sy == p)
break
endif
0.5::@&run %vo,%vp
endloop
return next
%scene 撿四方
(r=%sx*65536+%sy)
(u=0)
if (o==%sx-1 && p==%sy)
do(true)
1:get_bc:get w
if(u!=0)
break
endif
enddo
return next
endif
if (o==%sx+1 && p==%sy)
do(true)
1:get_bc:get e
if(u!=0)
break
endif
enddo
return next
endif
if (o==%sx && p==%sy+2)
do(true)
1:get_bc:get s
if(u!=0)
break
endif
enddo
return next
endif
if (o==%sx && p==%sy-2)
do(true)
1:get_bc:get n
if(u!=0)
break
endif
enddo
return next
endif
toreal %vr (5,9) s
if (q==s)
do(true)
1:get_bc:get ne
if(u!=0)
break
endif
enddo
return next
endif
toreal %vr (5,11) s
if (q==s)
do(true)
1:get_bc:get se
if(u!=0)
break
endif
enddo
return next
endif
toreal %vr (4,9) s
if (q==s)
do(true)
1:get_bc:get nw
if(u!=0)
break
endif
enddo
return next
endif
toreal %vr (4,11) s
if (q==s)
do(true)
1:get_bc:get sw
if(u!=0)
break
endif
enddo
return next
endif
do(true)
1:get_bc:get %vr
if(u!=0)
break
endif
enddo
return next
%scene 全撿
1:get_bc:@%%1
return next↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。