本篇收录 3 节5,461 字与表格内容
查看本篇的全部关联 使用前，先确认这些设置
- 修改h实际值35为自己的基础负重；原注释的h=30已不是本稿当前值。
- 五坑中心6/24/42/60/78,42，home第一坑；原说明要求定位6,8、第一坑银行、第五坑药店与指定柜台相对位置。
- 五坑主体只打怪，需另配拾取端；额外十只的sellten才包含完整拾卖。
来源脚本供研究参考，未在当前游戏环境运行验证。
01用途与执行流程
IKOK 2.2.7以上旧稿，依五坑与额外十只轮转，吸魂补MP、冰矛输出，自己拾取额外十只的掉落。
- 从安全区或当前位置整理负重，回第一坑home点；等待周期按t8=380计时。
- 五坑逐一等刷新、吸魂到距满MP不足200，再冰矛配recall 8检测战斗。
- 到80,24引额外十只，在80,26可见柜台处打、拾、卖；必要时买黄色药水或膏药。
- 22:58后转安全点7,12等待，结束再从begin开始。
02这份代码的适用限制
03完整代码
384 行原文
#掛機請使用IKOK2.2.7以上版本！
#代碼沒有每輪的收益統計，每次代碼啟動時會在LOG記錄銀行存款，自己根據兩天的銀行存款差計算收益；
#【1】你必須做的第一件事：begin段裡(h=30)的數值改成你的裸負重，身上除了穿了的裝備和保護令以外不要放其他東西；
#【2】你必須做的第二件事：home點定在第一坑，定位術定在座標 6,8 ；第一坑放一個銀行，第五坑放一個藥店，都挨著櫃檯上面做；
#【3】你必須做的第三件事：1-4坑櫃檯做在（5,4），第5坑櫃檯做在（5,3）；
#【4】你必須做的第四件事：櫃檯和home點的配置都做好後，用代碼把MOB改成自動攻擊屬性，然後手動打一遍看看是否有遺漏，確定無誤就可以開始掛機了；
#掛機請使用IKOK2.2.7以上版本！
%var a
6,42
24,42
42,42
60,42
78,42
#如果用藍達打坑 下面變數改成1
%var ld
0
%var h
35
#↓引怪座標
%var d
80,24
#↓單獨10個賣裝備能看到櫃檯的座標
%var e
80,26
# 10人能看到櫃檯的縱座標
%var ey
26
#安全區定位座標，最好是時空門，放些銀行草人英雄會館什麼的
%var j
7,12
#後面的部分不要修改
%var b
(5,8)
(5,9)
(6,10)
(5,11)
(5,12)
(4,11)
(4,10)
(4,9)
#↓吸魂目標
%var g
a
b
c
d
e
f
g
h
i
j
%var o
%var y
(5,12)
#↓h的值是你的裸負重，必須修改
%scene begin
1::sing 聚精會神，擼一發大的....
foreach o
remove o %vo
loop
if (%sy<15)
jump sktokill
else
jump ready
endif
%scene sktokill
0.5::sing 大保健做完了，走，搬磚去。。。。
(k=0)
::%za
5:home_bc:home me
wait1
run %va 10
if(%heft>h)
call heft
endif
(t8=380)
(t1=%now)
jump gogogo
%scene heft
loop5
1:click_bc:@&click 櫃檯(counter)
endloop
loop4
0.34:sell_bc:sell 2
endloop
loop4
0.34:sell_bc:sell 3
endloop
return
#↓打錢準備段，不用改
%scene ready
0.35::sing 走，整點嫖資去....
1::s
1::s
loop4
5:cast_bc:cast ice_lance on %vy
endloop
1::s
1::s
call fackall
#5:home_bc:cast location on me
run %vj 50
call fackall
run %vj 50
loop39
10::wait
endloop
::%za
5:home_bc:home me
wait1
run %va 50
if(%heft>h)
call heft
endif
(t8=380)
(t1=%now)
jump gogogo
#↓打錢段
%scene gogogo
foreach a
run %va 50
::%ik
if(%sx < 16)
do (true)
2:consider_bc:consider a
enddo
endif
call kill
if (%h<%H/3)
0.4::@&click 草藥店櫃檯
0.34::buy yellow potion
0.34::drink potion
endif
if ((%h<%H/2) && (%h>%H/3))
0.4::@&click 草藥店櫃檯
0.34::buy plaster
0.34::apply plaster
endif
if ( %hh == 22 && %mm >= 58 )
jump wait
endif
add o %now
if(k>5)
call timex
endif
loop
run %vd 50
::%ik
2.5::sing 本次開始時間^[33m %vt1 ^[32m！本次收入^[33m %g ^[32m金幣！這是第 %il 輪！
run %ve 10
call killten
add o %now
loadmapvar corpse c
call sellten
clearmapvar corpse
jump jishi
%scene jishi
if(%h<%H-50)
0.4::@&click 草藥店櫃檯
0.34::buy plaster
0.34::apply plaster
endif
if(k>5)
call timex
endif
(t1=%now)
5:home_bc:home me
jump gogogo
%scene timex
0.5::e
do (true)
(t3=%now-o)
if(t3 >= t8)
break
else
(t5=t8-t3)
0.5::sing 距離下一坑重新整理還有 %vt5 秒，我想靜靜......
endif
enddo
remove o %vo
return
%scene drink
priority
if (%h<%H/3)
0.4::@&click 草藥店櫃檯
0.34::buy yellow potion
0.34::drink potion
endif
return retry
%scene kill
1::sing 本次開始時間 %vt1 ！上次收入^[33m %vz 金幣！本次收入 %g 金幣！這是本次第 %vk 坑！
do (%m<%M-200)
#5:soul_bc:soul_steal %vg
5:soul_bc:cast soul_steal on %vg
::%ig
enddo
if (ld > 0)
3:dragon:cast dragon_breathe on
endif
do(true)
#0.4::cast black_flame on
0.4::cast ice_lance on
0.4:recall8_bc:recall 8
enddo
return
%scene sellten
toreal b s
0.34::@&click 櫃檯
foreach s
if(%vs in c)
remove c %vs
do(true)
1:get_bc:get ALL_ITEM_IN %vs
enddo
endif
do(%heft>h)
0.34:sell_bc:sell 1
enddo
loop
greedy c t
foreach t
run %vt
0.34::@&click 櫃檯
loadround c s
foreach s
remove c %vs
do(true)
1:get_bc:get ALL_ITEM_IN %vs
enddo
if (%sy<ey)
run %ve 10
0.34::@&click 櫃檯
endif
do(%heft>h)
0.34:sell_bc:sell 1
enddo
loop
loop
return
%scene killten
do (%m<%M-200)
5:soul_bc:cast soul_steal on %vg
::%ig
enddo
if (ld > 0)
3:dragon:cast dragon_breathe on
endif
do(true)
#0.4::cast black_flame on
0.4::cast ice_lance on
0.4:recall8_bc:recall 8
enddo
return
%scene fack
1::s
loop5
#5:cast_bc:cast black_flame on
5:cast_bc:cast ice_lance on
endloop
1::s
loop5
wait1
#5:cast_bc:cast black_flame on
5:cast_bc:cast ice_lance on
endloop
return
%scene fackall
1::s
loop5
#5:cast_bc:cast black_flame on
5:cast_bc:cast ice_lance on
endloop
1::s
loop5
wait1
#5:cast_bc:cast black_flame on
5:cast_bc:cast ice_lance on
endloop
return
%scene wait
#5:home_bc:cast location on me
run %vj 50
log 風緊，扯呼....到安全區等重啟了......
run %vj 3
loop100
#5:sum_bc:cast dark_soul
#5:steal_bc:soul_steal %vy
wait1
#2:kill_bc:kill %vy
endloop
jump begin
#↓-------------------------判-斷-區----------------------------------
%bc time_bc
next:0.34:%b中原不標準時間:%*
%bc sc_bc
next:0.34:%b%*銀行裡還有%+枚金幣
%bc click_bc
break::這是一張生意場所經常使用來記帳的櫃檯。
break::這是一張銀行使用來記帳的櫃檯。
%bc consider_bc
break::你用挑釁的眼光上下打量%*
%bc kill_bc
retry:0.34:你正忙著呢 !
retry:0.34:你上一個動作沒有%*
next:0.34:你喝道%*
%bc recall_bc
retry:0.34:你正忙著%*
retry:0.34:你上一個動作沒有%*
retry:0.34:然而什麼事也沒有發%*
retry:1:你現在正在戰鬥%*
%bc recall8_bc
break::你祈求神把你帶回愛的小屋 ...
retry:0.34:你正忙%*
%bc home_bc
retry:0.34:你正忙著%*
retry:0.34:你上一個動作沒有%*
retry:0.34:然而什麼事也沒有發%*
next:5:你的身體散發出淡淡的微光，轉眼間%*
next:1:你進入區域%*位置在%*
call:fack:你正在戰鬥%*
%bc soul_bc
retry:0.34:你上一個動作沒有完成%*
retry:0.34:(你發出的命令過多了, 每秒超過3個%*
retry::你流了一身的冷汗, 不過什麼也沒有發%*
retry::你正忙著呢, 沒有空使用吸魂%*
retry:0.34:你要對誰施展吸魂術呢 ?
next:0.34:(你感到一股精神力量被吸納到你%*
next:0.34:你要有目標才能施法%*
retry:0.4:你正忙著%*
retry:0.4:但是什麼事也%*
retry:0.4:你沒有學過這%*
retry:0.4:你上一個動作沒有完成%*
retry:0.4:你面前的符咒突然爆炸%*
next:0.4:%*的四周似乎突然塌陷下去%*
next:0.4:那裡沒有任%*
next:0.4:%*鎮定地與你的法力抗衡%*
next:0.4:你覺得一股能量不斷%*
next:0.4:你現在不在戰鬥%*
next:0.4:你要有目標才能%*
next:0.4:你的法術失效%*
next:0.4:你附近沒有這個人%*
%bc cast_bc
retry:0.34:你正忙著%*
retry:0.34:但是什%*事也%*
retry:0.34:你沒有學過這%*
retry:0.34:你上一個動作沒有完成%*
retry:0.34:你劃出來的符咒突然%*
next:0.34:你喃喃念道 : 黑暗的原火啊, 永無止境地%*
next:0.34:那裡沒有任何人。
break::你現在不在戰鬥中%*
break::你附近沒有這個人%*
break::你要有目標才能施法%*
retry:1:你的法力不夠%*
%bc get_bc
retry:0.34:你上一個動作沒有%*
break:0.34:這裡沒有任何東%*
break:0.34:你的附近沒有這種東西。
break:0.34:你撿起%*
%bc sell_bc
break:0.34:你不能把這個東西賣%*
break:0.34:what ?
break:0.34:這個東西你正裝備%*
break:0.34:你無法與你視線範圍外的商店進行交易 ...
%bc sum_bc
next:0.34:一道充滿了魔法力量的光芒%*
retry:0.34:你上一個動作沒有完成%*
retry:0.34:但是什%*事也沒發生%*
retry:0.34:你面前的魔法六角星突然崩潰%*
retry:0.34:你正忙%*
%bc steal_bc
retry:0.34:你正忙著呢%*
retry:0.34:你上一個動作沒有完成%*
retry:0.34:你流了一身的冷汗, 不過什麼也沒有%*
retry:0.34:你正忙著呢, 沒有空使用吸魂術%*
next:1:(你感到一股精神力量被吸納到你%*
next:0.34:你要對誰施展吸魂術呢 ?
next:0.34:%*已經沒有精神力可供你吸取了 ...
next::這裡沒有這個人喔 ...
next::你的目標已經走遠了 ...
%public_bc
next:0.34:你要往哪個方向 ?
retry:1:你剛剛才轉換過區域%*
call:drink:%h<100↗来源与版本
飞梦／17KOK、渔夫与2001年典藏版出现数值或机制冲突时，以飞梦所记相应服务器的后续有效规则为正文依据；同站更新按明确生效日期处理。旧规则保留年代与服别，未明日期的差异就近说明；原资料对照用于追溯。